Введение

Цель:

Научиться оформлять работы в виде документа
Научиться базовым понятиям: переменная, функция, массивы, установки пакетов
Освоить пакет Plots для построения графиков
Освоить пакет Roots для решения уравнений
Освоить пакет NLsolve для решения систем уравнений

Текстовое оформление

В инженерных расчетах требуется не только вычисления, но и пояснения к вычисленим. Поэтому даная концепция в виде интерактивных блокнотов (notebook) внедрена во многие практические рализаци для написания кода: среду engee, пакеты Pluto и Jupiter

Примечание

название данного пакета складывается из трех языков программрования julia, python и R

Для оформления текстаиспользуется язык язык ращзметки Markdown.
Элементы базового синтаксиса:

# Заголовок первого уровня
## Заголовок второго уровня

*текст курсивом*
**жирный текст**

> Цитата

Нумерованый список:
1. Элемент нумерованного списка
2. Элемент №2 того же списка
9. Элемент №3 списка — элементы нумеруются по порядку, цифра в начале строки не имеет значения

Маркированый список:
* элемент маркированного списка
- ещё один элемент ненумерованного списка
+ буллеты элементов могут быть разными

`исходный код программы` будет написан моноширный шрифтом

[ссылка](https://www.kstu.ru)

| Таблица | заголовок |
| ----------- | ----------- |
| поле таблицы | поле таблицы |
| поле таблицы | поле таблицы |

Внутри текста можно написать формулу с использованием языка разметки . Текст формулы ограничивается с двух сторон знаком $

Некоторые примеры:

a = 10

10

Внутри текстовых блоков можно выводить значения переменных. Для этого ставится $(имя переменной).

Пример: значение переменной a равно $(a)

Примечание

Если в конце выражения для вычисления стоит ;то результат вычисления не будет выводиться на экран

Переменные

Переменная - именованная область памяти, хранящая какие-либо данные. В зависимости от типа переменной выделяется различное количество памяти. В основном для расчето будут использоваться следующие типы:

целые числа Int64
дробные числа (числа с плавающей точкой) Float64
текстовые переменные

b = 10    	#целочисленная переменная

10

c = 0.456    #переменная с плавающей точкой

0.456

d = "text"   #текстовая переменная

"text"

Примечание

Текст после знака # является комнтарием и не исполняется как код программы

Посмотреть тип какой-либо переменной можно с использованием функции typeof()

typeof(b)

Int64

typeof(c)

Float64

typeof(d)

String

Функции

Часто повторяющие действия в програмировании объединяются в функции.

Функции в julia записываются через блок function - end. В скобочках записываются аргументы функции.

function myfunction(x)
	return x^2
end

myfunction (generic function with 1 method)

myfunc2(x) = x^2

myfunc2 (generic function with 1 method)

Для одной и той же функции можно задать различные методы реализации в зависимости от того сколько аргументов у функции и какого типа дынные переменные.

myfunc2(x::Int64) = 1/x

myfunc2 (generic function with 2 methods)

Теперь при вызове функции myfunc() результат будет определяться типом аргумента. Если аргумент будет целочисленный:

myfunc2(10) = $(myfunc2(10))

если число с плавающей точкой:

myfunc2(10.0) = $(myfunc2(10.0))

Примечание

Старайтесь называть переменные и функции так, чтобы было понятно что они хранят или что делают.

Массивы

Часто в инженерных расчетах применяются массивы. Переменные которые хранятне множество знаений.

В химической технологии наиболее часто применяются одномерные массивы - векторы. Например, при проведении нескольких экспериментов измеренные величины хранятся в соотвествующих массивах.

Пример задания массива с целочисленными значениями:

arr1 = [1, 2, 3, 4]   #массив с целочисленными значениями

4-element Vector{Int64}:
 1
 2
 3
 4

typeof(arr1)

Vector{Int64} (alias for Array{Int64, 1})

arr2 = [1.0, 2, 3, 4, 5, 6, 7 ,9]

8-element Vector{Float64}:
 1.0
 2.0
 3.0
 4.0
 5.0
 6.0
 7.0
 9.0

typeof(arr2)

Vector{Float64} (alias for Array{Float64, 1})

Нумерация массивов начинается с единицы. В отличие от многих других языков программирования.

arr2[1]   #первый элемент массива

1.0

arr2[2:4]   #массив содержащий срез массива с элементами от 2 до 4

3-element Vector{Float64}:
 2.0
 3.0
 4.0

arr2[3:end]   #массив с 3 элемента и до конца массива

6-element Vector{Float64}:
 3.0
 4.0
 5.0
 6.0
 7.0
 9.0

length(arr2)    #размер массива (количество элементов)

8

В случае если изначально размер массива неизвестен, то можно создать пустой массив. А потом добавить лять в него новые значения с использованием функции push!

arr3 = []

Any[]

push!(arr3, 1)

1-element Vector{Any}:
 1

push!(arr3, 3)

2-element Vector{Any}:
 1
 3

push!(arr3, 6)

3-element Vector{Any}:
 1
 3
 6

В julia принято в функциях, меняющишх значение аргументов в названии использовать восклицательный знак. В данном случае меняется значение аргумента arr3.

Однако время выполнения функции push! очень большое, поэтому ее лучше не использовать (или использовать не часто).

Поэтому можно создавать массивы с заданными размерами. Для этого можно использовать функцию zeros. Создующую массив из нулей.

zeros(Float64, 10)   #массив из 10 чисел с плавающей точкой заполнгеный нулями

10-element Vector{Float64}:
 0.0
 0.0
 0.0
 0.0
 0.0
 0.0
 0.0
 0.0
 0.0
 0.0

arr4 = zeros(Int64, 10)    #массив из 10 целых чисел заполнгеный нулями

10-element Vector{Int64}:
 0
 0
 0
 0
 0
 0
 0
 0
 0
 0

А после уже заполнить массив нужными значениями. Например:

arr4[1] = 5

5

arr4

10-element Vector{Int64}:
 5
 0
 0
 0
 0
 0
 0
 0
 0
 0

Удобно задавать массивы с использованием функции collect. Например создадим массив из 10 чисел от 1 до 10 содержащий квадраты индексов:

collect(i^2 for i = 1:10)

10-element Vector{Int64}:
   1
   4
   9
  16
  25
  36
  49
  64
  81
 100

Также можно внутри цикла можно проверять значения. Например к предыдущему примеру добавим условие, что куб от индекса должен быть меньше 100:

arr6 = collect(i^2 for i = 1:10 if i^3 < 100)

4-element Vector{Int64}:
  1
  4
  9
 16

Матричные и поэлементные операторы.

В случае умножения или деления двух матриц используя знак умножения происходит матричное умножение. Однако чаще применяется поэлементные операции, когда операция провордится для элементов с одинаковыми индексами. Для поэлементных операций ставится точка перед знаком умножения (или деления).

При использовании массивов в качестве аргумента функции должна быть реализация метода этой функции для массива в качестве аргумента. Другим вариантом является применение функции для каждого элеменат массива. Для этого в конце названия функции ставится точка.

mata = [1 2 3; 2 3 4; 1 3 5]

3×3 Matrix{Int64}:
 1  2  3
 2  3  4
 1  3  5

matb = [2 3 4; 5 6 7; 2 4 56]

3×3 Matrix{Int64}:
 2  3   4
 5  6   7
 2  4  56

mata * matb    #матричное умножение

3×3 Matrix{Int64}:
 18  27  186
 27  40  253
 27  41  305

mata .* matb   #поэлементное умножение

3×3 Matrix{Int64}:
  2   6   12
 10  18   28
  2  12  280

exp.(mata)		#поэлементное применение экспоненты

3×3 Matrix{Float64}:
 2.71828   7.38906   20.0855
 7.38906  20.0855    54.5982
 2.71828  20.0855   148.413

Размерности (пакет Unitful)

На практике у физиеческих переменных есть не только значение, но и размерность. Обычно расчеты ведутся в единой системе (в хим технологии принято СИ). И много ошибок в расчетах бывают связаны именно с тем, что некоторые значения не были приведены в единую систему.

Отловить такие ошибки можно с использованием пакета Unitful. Данный пакет позволяет к переменным добавить размерности.

Для примера найдем объем ящика при известных длинах сторон.

using Unitful

box_a = 10.8u"cm"    #сторона ящика 10.8 сантиметров

10.8 cm

box_b = 200.9u"mm"    #сторона ящика 200.9 миллиметров

200.9 mm

box_c = 3u"m"    #сторона ящика 3 метра

3 m

box_v = box_a * box_b * box_c    #находим объем бокса

6509.160000000001 mm cm m

box_v |> u"m^3"     #объем ящика выраженная в кубических метрах

0.06509160000000001 m^3

box_v |> u"l"     #объем ящика выраженная в литрах

65.09160000000001 L

Построение графиков

Для построения графиков существует множество пакетов. Мы будем использовать пакет Plots.

Для построения графика в декартовых координатах необходимо задать два ветора с координатами по осям абсцисс и ординат.

Построим график функции и на этом же графике функцию косинуса в диапазоне от 0 до 10

using Plots

y(x) = sin(x)    #задаем функцию

y (generic function with 1 method)

px = 0:0.2:10     #задаем диапазон по x от 0 до 10 с шагом 0.2

0.0:0.2:10.0

py = y.(px)     #определяем значения функции для выбранного диапазона

51-element Vector{Float64}:
  0.0
  0.19866933079506122
  0.3894183423086505
  0.5646424733950354
  0.7173560908995228
  0.8414709848078965
  0.9320390859672263
  0.9854497299884601
  0.9995736030415051
  0.9738476308781951
  0.9092974268256817
  0.8084964038195901
  0.675463180551151
  ⋮
  0.998543345374605
  0.9893582466233818
  0.9407305566797731
  0.8545989080882805
  0.7343970978741133
  0.5849171928917617
  0.4121184852417566
  0.22288991410024764
  0.024775425453357765
 -0.17432678122297965
 -0.3664791292519284
 -0.5440211108893698

plot(px, py, label = "y(x)")    #строим график функции, подпись в легенду "y(x)"
plot!(px, cos.(px), label = "cos(x)", color = "red")   #график функции косинуса
xlabel!("x")    #подпись по оси x
ylabel!("y")    #подпись по оси y

Восклицательный знак в названии функции пакета Plots означает, что функция будет применена для текущего графика.

Обычно экспериментальные даные представляются на графике в виде точек, а не в виде линий.
Для построения графика в виде точек используется функция scatter.

pa = [1, 2, 3, 4, 5, 6]

6-element Vector{Int64}:
 1
 2
 3
 4
 5
 6

pb = [0.1, 0.4, 0.8, 1.8, 0.4, 0.9]

6-element Vector{Float64}:
 0.1
 0.4
 0.8
 1.8
 0.4
 0.9

scatter(pa, pb, label = "")    #строим график в виде точек, подпись в легенде убираем

Построение таблиц

Для построения таблиц с данными можно использовать пакет PrettyTables

Для примера построим таблицу со значениями из предыдущего задания.

using PrettyTables

pretty_table(HTML, hcat(pa,pb), header = ["Значения x", "Значение y"], title = "Таблица 1 со значениями")   #функция hcat объединяет массивы горизонтально

Решение уравнений

Для решения уравнений применяется пакет Roots.

Решение уравнения заключается в определении значения аргумента, при котором функция становится равной нулю. Поэтому уравнения вида:

преобразуются к виду:

Для численного решения уравнений применяются разные алгоритмы, но в большинстве случаев для работы алгоритма необходимо задать начальное приближение - значение с которого алгоритм начнет поиск. Чем ближе будет значение к корню тем быстрее будет произведен поиск.

Также у функции может быть несколько корней, поэтому в зависимости от наачльного приближения могут быть найдены различные корни.

using Roots

WARNING: using Roots.init in module Main conflicts with an existing identifier.

fz(x) = x^2 - 3 * x - 5

fz (generic function with 1 method)

find_zero(fz, 0.5)   #определение корня для начального приближения 0.5

-1.192582403567252

find_zero(fz, 10)   #определение корня для начального приближения 10

4.192582403567252

find_zeros(fz, (-10,10))   #определение всех корней в диапазоне от -10 до 10

2-element Vector{Float64}:
 -1.192582403567252
  4.192582403567251

Можно использовать анонимные функции, функции не имеющие названий. Анимные функции могут быть использованы, опрделяется корни функций нескольких переменных.

find_zero(x -> x^2 - 3*x -5, 0.1)   #пример применения анонимных функций

-1.192582403567252

Решение систем уравнений

Для решения систем уравнений применяется пакет NLsolve.

Решим систему:

Для решения преобразуем систему, чтобы в правой части от знака равно был ноль. Неизвестные перменные предаставляют в виде массива , таким образом искомое значение x в уравнении заменяем на x[1], а y на x[2].

using NLsolve

function urav(x)    #функция для определения корней (нулевых значений функции)
    [x[1]^2 + x[2]^2 - 10.0,
    x[2] - x[1]^2 + 3]
end

urav (generic function with 1 method)

sol = nlsolve(urav, [1.0,1.0])     #поиск решения для начального приближения [1, 1]

Results of Nonlinear Solver Algorithm
 * Algorithm: Trust-region with dogleg and autoscaling
 * Starting Point: [1.0, 1.0]
 * Zero: [2.278723855702863, 2.192582403643636]
 * Inf-norm of residuals: 0.000000
 * Iterations: 4
 * Convergence: true
   * |x - x'| < 0.0e+00: false
   * |f(x)| < 1.0e-08: true
 * Function Calls (f): 5
 * Jacobian Calls (df/dx): 5

sol.zero    	#корни уравнения

2-element Vector{Float64}:
 2.278723855702863
 2.192582403643636

sol2 = nlsolve(urav, [-1.0,-1.0])     #поиск решения для начального приближения [-1, -1]

Results of Nonlinear Solver Algorithm
 * Algorithm: Trust-region with dogleg and autoscaling
 * Starting Point: [-1.0, -1.0]
 * Zero: [1.3050887724637562e-8, -3.1701829335840506]
 * Inf-norm of residuals: 0.170183
 * Iterations: 1000
 * Convergence: false
   * |x - x'| < 0.0e+00: false
   * |f(x)| < 1.0e-08: false
 * Function Calls (f): 90
 * Jacobian Calls (df/dx): 40

sol2.zero    	#корни уравнения

2-element Vector{Float64}:
  1.3050887724637562e-8
 -3.1701829335840506

Методы решения инженерных задач

Введение

Текстовое оформление

Переменные

Функции

Массивы

Матричные и поэлементные операторы.

Размерности (пакет Unitful)

Построение графиков

Построение таблиц

Решение уравнений

Решение систем уравнений

类型

简要说明

相关帖子

标签

类别

语言

格式

级别

现状

已发布

已更新

来源