AnyMath 文档
Notebook

最大化长期投资

导言

这个例子提出了优化长期固定收益投资组合的任务。 目标是通过将不同期限和利率的债券的收入再投资,在给定的规划范围内最大化最终资本。 该研究演示了使用线性规划方法来形式化和解决这个问题。

设置任务

让我们考虑一个投资模型,在给定的时间范围内,固定的初始资本分布在具有确定性回报的债券之间。 每种债券的特点是年资本化的固定利率和到期时累积利息收入的名义价值支付。 该模型的目标函数旨在使投资期结束时的总资本最大化。

此外,该模型可能包括对投资组合多样化的限制,该限制设定了单笔投资在配售时资本总额中的最大份额。

研究方法涉及一步一步地考虑这个问题:从一个有限的工具集的特殊情况到一个广义的公式。 问题的数学形式化是在线性规划装置的框架内实现的,这使得可以制定和解决最大化最终福祉的相应优化问题。

介绍性例子

让我们来看一个初始资本为1,000卢布,投资期限为5年的演示示例。 该模型包括四种不同特征的债券:债券1在第一年购买,期限为4年,收益率为2%;债券2在第五年购买,期限为1年,收益率为4%;债券3和4在第二年购买,

为了模拟非投资基金,引入了五种一年期零收益债券,形成了九种投资工具的等价模型。

添加必要的库和可视化功能:

In [ ]:
import Pkg 
Pkg.add(["JuMP", "HiGHS"])
In [ ]:
using Plots, Random, JuMP, HiGHS
include("plotInvest.jl")
Out[0]:
plotInvest (generic function with 1 method)

我们使用表示每个债券可用购买期限的水平矩形来可视化此任务。 利率债券的数量沿着这条线排列。 以年为单位的投资期列于各栏中。

In [ ]:
# 年的时间段
Период = 5
# 债券数目
КоличествоОблигаций = 4
# 初始金额
Сумма_0 = 1000
# 购买选项总数
ВсегоВозможностейПокупки = КоличествоОблигаций + Период
# 购买期限
ГодыПокупки = [1; 2; 3; 4; 5; 1; 5; 2; 2]
# 债券期限
СрокПогашения = [1; 1; 1; 1; 1; 4; 1; 4; 3]
# 债券发售期
ГодыПогашения = ГодыПокупки .+ СрокПогашения .- 1
# 利率百分比
Проценты = [0; 0; 0; 0; 0; 2; 4; 6; 6]
# 一年后收益率,包括利息
ДоходностьЗаГод = 1 .+ Проценты ./ 100
# 任务可视化
p1 = plotInvest(КоличествоОблигаций, ГодыПокупки, СрокПогашения, Проценты)
display(p1)
No description has been provided for this image
GKS: could not find font middle.ttf

可变解决方案

让我们用向量x来表示解变量,其中 -投资于债券k的卢布金额,对于k=1,。..,9. 偿还后,投资的付款 等于:

In [ ]:
# 创建优化模型
модель = Model(HiGHS.Optimizer)
# 可变解决方案-投资金额
@variable(модель, x[1:ВсегоВозможностейПокупки] >= 0)
# 总回报
ОбщаяДоходность = ДоходностьЗаГод .^ СрокПогашения
Out[0]:
9-element Vector{Float64}:
 1.0
 1.0
 1.0
 1.0
 1.0
 1.08243216
 1.04
 1.2624769600000003
 1.1910160000000003

目标功能

优化的目的是使可赎回债券的收入再投资所产生的总资本最大化。 正如图形可视化所示,在过渡期间收到的现金流量被再投资,并有助于形成最终的福利。

让我们创建一个目标函数和一个任务来最大化。

In [ ]:
# 创建优化任务(最大化)
@objective(модель, Max, x[5] * ОбщаяДоходность[5] + x[7] * ОбщаяДоходность[7] + x[8] * ОбщаяДоходность[8])
Out[0]:
$ x_{5} + 1.04 x_{7} + 1.2624769600000003 x_{8} $

线性约束

该模型假设每年在投资工具之间分配可用资本。 在初始阶段,种子资本被放置,在随后的时期,可赎回债券的现金流量被再投资。

让我们做一个方程组:

In [ ]:
# 投资限制
@constraint(модель, ограничение_инвестиции1, x[1] + x[6] == Сумма_0)
@constraint(модель, ограничение_инвестиции2, x[2] + x[8] + x[9] == ДоходностьЗаГод[1] * x[1])
@constraint(модель, ограничение_инвестиции3, x[3] == ДоходностьЗаГод[2] * x[2])
@constraint(модель, ограничение_инвестиции4, x[4] == ДоходностьЗаГод[3] * x[3])
@constraint(модель, ограничение_инвестиции5, x[5] + x[7] == ДоходностьЗаГод[4] * x[4] + ОбщаяДоходность[6] * x[6] + ОбщаяДоходность[9] * x[9])
Out[0]:
$$ -x_{4} + x_{5} - 1.08243216 x_{6} + x_{7} - 1.1910160000000003 x_{9} = 0 $$

决定

我们将解决这个问题,不限制可以投资于一个债券的金额。

In [ ]:
optimize!(модель)
решение = value.(x)
значение_целевой_функции = objective_value(модель)
Running HiGHS 1.12.0 (git hash: 755a8e027a): Copyright (c) 2025 HiGHS under MIT licence terms
LP has 5 rows; 9 cols; 15 nonzeros
Coefficient ranges:
  Matrix  [1e+00, 1e+00]
  Cost    [1e+00, 1e+00]
  Bound   [0e+00, 0e+00]
  RHS     [1e+03, 1e+03]
Presolving model
2 rows, 6 cols, 9 nonzeros  0s
1 rows, 4 cols, 4 nonzeros  0s
0 rows, 0 cols, 0 nonzeros  0s
Presolve reductions: rows 0(-5); columns 0(-9); nonzeros 0(-15) - Reduced to empty
Performed postsolve
Solving the original LP from the solution after postsolve

Model status        : Optimal
Objective value     :  1.2624769600e+03
P-D objective error :  0.0000000000e+00
HiGHS run time      :          0.04
Out[0]:
1262.4769600000004

解决方案的可视化

让我们展示投资回报的价值。

In [ ]:
println("После $Период лет, доход с начальных $(Сумма_0) ₽ составит $(round(значение_целевой_функции, digits=2)) ₽")
После 5 лет, доход с начальных 1000 ₽ составит 1262.48 ₽

可视化解决方案:

In [ ]:
p2 = plotInvest(КоличествоОблигаций, ГодыПокупки, СрокПогашения, Проценты, решение)
display(p2)
No description has been provided for this image

有限的最佳投资

为确保投资组合多样化,该模型对单个资产的投资相对于本期总资本(包括可赎回证券的收益)的最大份额提出了限制。

In [ ]:
# 为具有约束的问题创建模型
модель_с_ограничениями = Model(HiGHS.Optimizer)
# 约束模型的决策变量
@variable(модель_с_ограничениями, x2[1:ВсегоВозможностейПокупки] >= 0)
# 目标功能
@objective(модель_с_ограничениями, Max, x2[5] * ОбщаяДоходность[5] + x2[7] * ОбщаяДоходность[7] + x2[8] * ОбщаяДоходность[8])
# 基本投资限制
@constraint(модель_с_ограничениями, инвестиции1, x2[1] + x2[6] == Сумма_0)
@constraint(модель_с_ограничениями, инвестиции2, x2[2] + x2[8] + x2[9] == ДоходностьЗаГод[1] * x2[1])
@constraint(модель_с_ограничениями, инвестиции3, x2[3] == ДоходностьЗаГод[2] * x2[2])
@constraint(модель_с_ограничениями, инвестиции4, x2[4] == ДоходностьЗаГод[3] * x2[3])
@constraint(модель_с_ограничениями, инвестиции5, x2[5] + x2[7] == ДоходностьЗаГод[4] * x2[4] + ОбщаяДоходность[6] * x2[6] + ОбщаяДоходность[9] * x2[9])
# 投资于任何债券的最高利率
МаксПроцент = 0.6
Out[0]:
0.6

让我们创建一个不平等的系统:

In [ ]:
# 最大投资额的限制
@constraint(модель_с_ограничениями, лимит1, x2[1] <= МаксПроцент * Сумма_0)
@constraint(модель_с_ограничениями, лимит2, x2[2] <= МаксПроцент * (ДоходностьЗаГод[1] * x2[1] + ДоходностьЗаГод[6] * x2[6]))
@constraint(модель_с_ограничениями, лимит3, x2[3] <= МаксПроцент * (ДоходностьЗаГод[2] * x2[2] + ДоходностьЗаГод[6]^2 * x2[6] + ДоходностьЗаГод[8] * x2[8] + ДоходностьЗаГод[9] * x2[9]))
@constraint(модель_с_ограничениями, лимит4, x2[4] <= МаксПроцент * (ДоходностьЗаГод[3] * x2[3] + ДоходностьЗаГод[6]^3 * x2[6] + ДоходностьЗаГод[8]^2 * x2[8] + ДоходностьЗаГод[9]^2 * x2[9]))
@constraint(модель_с_ограничениями, лимит5, x2[5] <= МаксПроцент * (ДоходностьЗаГод[4] * x2[4] + ДоходностьЗаГод[6]^4 * x2[6] + ДоходностьЗаГод[8]^3 * x2[8] + ДоходностьЗаГод[9]^3 * x2[9]))
@constraint(модель_с_ограничениями, лимит6, x2[6] <= МаксПроцент * Сумма_0)
@constraint(модель_с_ограничениями, лимит7, x2[7] <= МаксПроцент * (ДоходностьЗаГод[4] * x2[4] + ДоходностьЗаГод[6]^4 * x2[6] + ДоходностьЗаГод[8]^3 * x2[8] + ДоходностьЗаГод[9]^3 * x2[9]))
@constraint(модель_с_ограничениями, лимит8, x2[8] <= МаксПроцент * (ДоходностьЗаГод[1] * x2[1] + ДоходностьЗаГод[6] * x2[6]))
@constraint(модель_с_ограничениями, лимит9, x2[9] <= МаксПроцент * (ДоходностьЗаГод[1] * x2[1] + ДоходностьЗаГод[6] * x2[6]))
Out[0]:
$$ -0.6 x2_{1} - 0.612 x2_{6} + x2_{9} \leq 0 $$

通过有限的多样化(每个资产的最大资本的60%)解决问题表明,与无限优化相比,最终盈利能力下降。 由此产生的投资组合的可视化显示了投资流的重新分配。

In [ ]:
# 用约束解决问题
optimize!(модель_с_ограничениями)
решение2 = value.(x2)
значение_целевой_функции2 = objective_value(модель_с_ограничениями)
Running HiGHS 1.12.0 (git hash: 755a8e027a): Copyright (c) 2025 HiGHS under MIT licence terms
LP has 14 rows; 9 cols; 46 nonzeros
Coefficient ranges:
  Matrix  [6e-01, 1e+00]
  Cost    [1e+00, 1e+00]
  Bound   [0e+00, 0e+00]
  RHS     [6e+02, 1e+03]
Presolving model
7 rows, 6 cols, 25 nonzeros  0s
Dependent equations search running on 2 equations with time limit of 1000.00s
Dependent equations search removed 0 rows and 0 nonzeros in 0.00s (limit = 1000.00s)
4 rows, 6 cols, 19 nonzeros  0s
Presolve reductions: rows 4(-10); columns 6(-3); nonzeros 19(-27) 
Solving the presolved LP
Using EKK dual simplex solver - serial
  Iteration        Objective     Infeasibilities num(sum)
          0    -3.3024705065e+00 Ph1: 4(3.57078); Du: 3(3.30247) 0s
          3    -1.2077779546e+03 Pr: 0(0) 0s

Performed postsolve
Solving the original LP from the solution after postsolve

Model status        : Optimal
Simplex   iterations: 3
Objective value     :  1.2077779546e+03
P-D objective error :  9.4089971014e-17
HiGHS run time      :          0.00
Out[0]:
1207.7779545600001

让我们在考虑到限制的情况下显示收入值:

In [ ]:
println("После $Период лет, доход с начальных $(Сумма_0) ₽ составит $(round(значение_целевой_функции2, digits=2)) ₽")
После 5 лет, доход с начальных 1000 ₽ составит 1207.78 ₽

可视化解决方案:

In [ ]:
# 具有约束的解决方案的可视化
p3 = plotInvest(КоличествоОблигаций, ГодыПокупки, СрокПогашения, Проценты, решение2)
display(p3)
No description has been provided for this image

自定义大小的模型

让我们继续讨论这个问题的广义表述,将模型扩展到30年的投资期限,400债券的投资组合随机回报在1-6%的范围内。 这种配置形成了具有430个变量的线性规划问题,证明了该方法对实际投资问题的适用性。

In [ ]:
Random.seed!(123)
# 初始金额
Сумма_0_большая = 1000
# 年的时间段
Период_большой = 30
# 债券数目
КоличествоОблигаций_большое = 400
# 购买选项总数
ВсегоВозможностейПокупки_большое = КоличествоОблигаций_большое + Период_большой
# 产生随机还款期限
СрокПогашения_большой = rand(1:(Период_большой-1), ВсегоВозможностейПокупки_большое)
# 债券的到期日为1年
СрокПогашения_большой[1:Период_большой] .= 1
# 我们为每个债券生成随机年利率
Проценты_большие = rand(1:6, ВсегоВозможностейПокупки_большое)
# 债券的利率为0(未投资)
Проценты_большие[1:Период_большой] .= 0
# 一年后收益率,包括利息
ДоходностьЗаГод_большая = 1 .+ Проценты_большие ./ 100
# 计算每只债券在到期期结束时的收益率
ОбщаяДоходность_большая = ДоходностьЗаГод_большая .^ СрокПогашения_большой
# 为每个选项创建随机购买年份
ГодыПокупки_большие = zeros(Int, ВсегоВозможностейПокупки_большое)
# 这些债券每年都可以购买
ГодыПокупки_большие[1:Период_большой] = 1:Период_большой
for i in 1:КоличествоОблигаций_большое
    # 生成随机年份以在T年期结束前偿还债券
    ГодыПокупки_большие[i+Период_большой] = rand(1:(Период_большой - СрокПогашения_большой[i+Период_большой] + 1))
end
# 计算每只债券在年底到期的期限
ГодыПогашения_большие = ГодыПокупки_большие .+ СрокПогашения_большой .- 1
Out[0]:
430-element Vector{Int64}:
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
  ⋮
 21
 24
 12
 21
 30
 21
 23
  6
 27
 22
 26
  4

让我们形成一个投资操作的临时模型,其中矩阵 индексы_покупки_большие 和 индексы_продажи_большие 每种金融工具的开仓和平仓可接受的期限都已设定。

In [ ]:
# 采购指数矩阵
индексы_покупки_большие = falses(ВсегоВозможностейПокупки_большое, Период_большой)
for ii in 1:Период_большой
    индексы_покупки_большие[:, ii] = ГодыПокупки_большие .== ii
end

# 销售指数矩阵
индексы_продажи_большие = falses(ВсегоВозможностейПокупки_большое, Период_большой)
for ii in 1:Период_большой
    индексы_продажи_большие[:, ii] = ГодыПогашения_большие .== ii
end

我们设置了对应于债券的优化变量。

In [ ]:
модель_большая = Model(HiGHS.Optimizer)
# 可变解决方案
@variable(модель_большая, x_большой[1:ВсегоВозможностейПокупки_большое] >= 0)
Out[0]:
430-element Vector{VariableRef}:
 x_большой[1]
 x_большой[2]
 x_большой[3]
 x_большой[4]
 x_большой[5]
 x_большой[6]
 x_большой[7]
 x_большой[8]
 x_большой[9]
 x_большой[10]
 x_большой[11]
 x_большой[12]
 x_большой[13]
 ⋮
 x_большой[419]
 x_большой[420]
 x_большой[421]
 x_большой[422]
 x_большой[423]
 x_большой[424]
 x_большой[425]
 x_большой[426]
 x_большой[427]
 x_большой[428]
 x_большой[429]
 x_большой[430]

让我们创建一个优化目标函数。

In [ ]:
# 最大化的任务
@objective(модель_большая, Max, sum(x_большой[индексы_продажи_большие[:, Период_большой]] .* ОбщаяДоходность_большая[индексы_продажи_большие[:, Период_большой]]))
# 限制
@constraint(модель_большая, НачальнаяИнвестицияБольшая, 
    sum(x_большой[i] for i in 1:ВсегоВозможностейПокупки_большое if индексы_покупки_большие[i, 1]) == Сумма_0_большая)

for t in 2:Период_большой
    @constraint(модель_большая, 
        sum(x_большой[i] for i in 1:ВсегоВозможностейПокупки_большое if индексы_покупки_большие[i, t]) ==
        sum(x_большой[i] * ОбщаяДоходность_большая[i] for i in 1:ВсегоВозможностейПокупки_большое if индексы_продажи_большие[i, t-1]))
end

让我们解决问题:

In [ ]:
@time optimize!(модель_большая)
решение_большое = value.(x_большой)
значение_целевой_функции_большое = objective_value(модель_большая)
Running HiGHS 1.12.0 (git hash: 755a8e027a): Copyright (c) 2025 HiGHS under MIT licence terms
LP has 30 rows; 430 cols; 823 nonzeros
Coefficient ranges:
  Matrix  [1e+00, 5e+00]
  Cost    [1e+00, 5e+00]
  Bound   [0e+00, 0e+00]
  RHS     [1e+03, 1e+03]
Presolving model
29 rows, 381 cols, 727 nonzeros  0s
24 rows, 304 cols, 545 nonzeros  0s
10 rows, 64 cols, 109 nonzeros  0s
8 rows, 47 cols, 77 nonzeros  0s
5 rows, 22 cols, 36 nonzeros  0s
4 rows, 18 cols, 28 nonzeros  0s
0 rows, 0 cols, 0 nonzeros  0s
Presolve reductions: rows 0(-30); columns 0(-430); nonzeros 0(-823) - Reduced to empty
Performed postsolve
Solving the original LP from the solution after postsolve

Model status        : Optimal
Objective value     :  5.7434911729e+03
P-D objective error :  0.0000000000e+00
HiGHS run time      :          0.00
  0.010847 seconds (3.72 k allocations: 326.055 KiB)
Out[0]:
5743.491172913259

投资效果如何?

In [ ]:
println("После $Период_большой лет, доход с начальных $(Сумма_0_большая) ₽ составит $(round(значение_целевой_функции_большое, digits=2)) ₽")
После 30 лет, доход с начальных 1000 ₽ составит 5743.49 ₽

有限股份的解决方案

让我们创建一个具有约束的优化问题:

In [ ]:
# 为具有约束的问题创建模型
модель_большая_с_ограничениями = Model(HiGHS.Optimizer)

@variable(модель_большая_с_ограничениями, x_большой_с[1:ВсегоВозможностейПокупки_большое] >= 0)
@objective(модель_большая_с_ограничениями, Max, 
    sum(x_большой_с[i] * ОбщаяДоходность_большая[i] for i in 1:ВсегоВозможностейПокупки_большое if индексы_продажи_большие[i, Период_большой]))

# 具有约束的模型的约束
@constraint(модель_большая_с_ограничениями, НачальнаяИнвестицияБольшаяС, 
    sum(x_большой_с[i] for i in 1:ВсегоВозможностейПокупки_большое if индексы_покупки_большие[i, 1]) == Сумма_0_большая)

for t in 2:Период_большой
    @constraint(модель_большая_с_ограничениями, 
        sum(x_большой_с[i] for i in 1:ВсегоВозможностейПокупки_большое if индексы_покупки_большие[i, t]) ==
        sum(x_большой_с[i] * ОбщаяДоходность_большая[i] for i in 1:ВсегоВозможностейПокупки_большое if индексы_продажи_большие[i, t-1]))
end

比例模型使用多样化标准,将单一债券在投资组合中的份额限制为0.4。

In [ ]:
МаксПроцент_большой = 0.4
Out[0]:
0.4

多样化约束的形式化需要构建两个数据结构:债券活动矩阵和当前价值矩阵,在此基础上确定投资组合中单个资产份额的上限。

In [ ]:
активные_большие = falses(ВсегоВозможностейПокупки_большое, Период_большой)
for ii in 1:Период_большой
    активные_большие[:, ii] = (ii .>= ГодыПокупки_большие) .& (ii .<= ГодыПогашения_большие)
end

我们将对最大投资设定限制。:

In [ ]:
# 最大投资额的限制
for i in 1:ВсегоВозможностейПокупки_большое
    for t in 1:Период_большой
        if индексы_покупки_большие[i, t]
            if t == 1
                @constraint(модель_большая_с_ограничениями, x_большой_с[i] <= МаксПроцент_большой * Сумма_0_большая)
            else
                @constraint(модель_большая_с_ограничениями, x_большой_с[i] <= МаксПроцент_большой * 
                    sum(x_большой_с[j] * (ДоходностьЗаГод_большая[j] ^ sum(активные_большие[j, 1:(t-1)])) 
                        for j in 1:ВсегоВозможностейПокупки_большое if активные_большие[j, t-1]))
            end
        end
    end
end

解决问题:

In [ ]:
@time optimize!(модель_большая_с_ограничениями)
решение_большое_с_ограничениями = value.(x_большой_с)
значение_целевой_функции_большое_с_ограничениями = objective_value(модель_большая_с_ограничениями)
println("\nПосле $Период_большой лет, доход с начальных $(Сумма_0_большая) ₽ составит $(round(значение_целевой_функции_большое_с_ограничениями, digits=2)) ₽")
Running HiGHS 1.12.0 (git hash: 755a8e027a): Copyright (c) 2025 HiGHS under MIT licence terms
LP has 460 rows; 430 cols; 72421 nonzeros
Coefficient ranges:
  Matrix  [4e-01, 5e+00]
  Cost    [1e+00, 5e+00]
  Bound   [0e+00, 0e+00]
  RHS     [4e+02, 1e+03]
Presolving model
419 rows, 430 cols, 72380 nonzeros  0s
Dependent equations search running on 28 equations with time limit of 1000.00s
Dependent equations search removed 0 rows and 0 nonzeros in 0.00s (limit = 1000.00s)
417 rows, 422 cols, 70114 nonzeros  0s
Presolve reductions: rows 417(-43); columns 422(-8); nonzeros 70114(-2307) 
Solving the presolved LP
Using EKK dual simplex solver - serial
  Iteration        Objective     Infeasibilities num(sum)
          0    -2.3043600253e+02 Ph1: 380(10201.3); Du: 102(230.436) 0s
        117    -5.7109808455e+03 Pr: 0(0) 0s

Performed postsolve
Solving the original LP from the solution after postsolve

Model status        : Optimal
Simplex   iterations: 117
Objective value     :  5.7109808455e+03
P-D objective error :  0.0000000000e+00
HiGHS run time      :          0.09
  0.105855 seconds (10.74 k allocations: 4.740 MiB)

После 30 лет, доход с начальных 1000 ₽ составит 5710.98 ₽

结果的定性分析

为了评估最佳投资组合的有效性,最好将其盈利能力与理论最大值进行比较-在整个30年期间,所有资本投资于最高利率为6%的债券。 分析的另一个指标可以是计算与所达到的最终福利水平相对应的等效年率。

In [ ]:
# 最大可能金额
максимальная_сумма = Сумма_0_большая * (1 + 6/100)^Период_большой

# 比率(百分比)
отношение = значение_целевой_функции_большое_с_ограничениями / максимальная_сумма * 100

# 等值利率
эквивалентная_ставка = ((значение_целевой_функции_большое_с_ограничениями / Сумма_0_большая)^(1/Период_большой) - 1) * 100

println("\nПолученная сумма составит $(round(отношение, digits=2))% от максимальной суммы $(round(максимальная_сумма, digits=2)) ₽,")
println("这可以通过投资一个债券来获得。")
println("\nВаш доход соответствует $(round(эквивалентная_ставка, digits=2))% годовой ставке за $(Период_большой)-летний период.")

# 可视化结果
p4 = plotInvest(КоличествоОблигаций_большое, ГодыПокупки_большие, СрокПогашения_большой, Проценты_большие, решение_большое_с_ограничениями, false)
display(p4)
Полученная сумма составит 99.43% от максимальной суммы 5743.49 ₽,
которая могла быть получена при инвестировании в одну облигацию.

Ваш доход соответствует 5.98% годовой ставке за 30-летний период.
No description has been provided for this image

图表显示了有限制的投资组合的时间结构:

*水平绿线-选定债券

*行首为购买年份,行尾为还款年份

*大括号{i}中的数字是键标识符

*自上而下的位置-投资优先

该图表显示了一个多元化的投资组合,其中投资按照每项资产不超过60%的限制分布在不同的年份和时期。

结论

所进行的研究证明了线性规划方法优化长期投资组合的有效性。 开发的模型可以确定在给定时间范围内最大限度地提高最终福祉的资本配置策略。

实验计算证实了多样化和盈利能力之间存在折衷:对一种资产份额的60%限制的引入与无限优化相比,最终收益率降低了4.3%。 该方法的可扩展性在具有30年期限和400债券组合的任务上得到验证。

未来研究的方向是考虑到盈利能力的不确定性,并在不断变化的市场条件下创建动态投资组合优化算法。