Шаблоны

@recipe(MyPlot, x, y, z) do scene
    Theme(
        plot_color = :red
    )
end

const MyPlot{ArgTypes} = Plot{myplot, ArgTypes}

myplot(args...; kw_args...) = ...
myplot!(args...; kw_args...) = ...

argument_names(::Type{<: MyPlot}) = (:x, :y, :z)

function default_theme(scene, ::MyPlot)
    Theme(
        plot_color => :red
    )
end

Makie.args_preferred_axis(::Type{<: MyPlot}, x, y, z) =  Makie.LScene

Makie.preferred_axis_type(plot::MyPlot) = Makie.LScene # если вам нужен весь объект графика в качестве информации.

function Makie.plot!(myplot::MyPlot)
    # обычный код построения графика, основанный на ранее определенных шаблонах
    # или атомарные операции построения графиков, добавляемые к объединенной функции `myplot`:
    lines!(myplot, rand(10), color = myplot.plot_color)
    plot!(myplot, myplot.x, myplot.y, myplot.z)
    myplot
end

const MyVolume = MyPlot{Tuple{<:AbstractArray{<: AbstractFloat, 3}}}
argument_names(::Type{<: MyVolume}) = (:volume,) # это также необязательно
function plot!(plot::MyVolume)
    # строим график объема с цветовой картой от полной прозрачности до plot_color
    volume!(plot, plot[:volume], colormap = :transparent => plot[:plot_color])
    plot
end

using CairoMakie

struct StockValue{T<:Real}
    open::T
    close::T
    high::T
    low::T
end

@recipe(StockChart) do scene
    Attributes(
        downcolor = :red,
        upcolor = :green,
    )
end

function Makie.plot!(
        sc::StockChart{<:Tuple{AbstractVector{<:Real}, AbstractVector{<:StockValue}}})

    # первым аргументом является наблюдаемый объект параметрического типа AbstractVector{<:Real}
    times = sc[1]
    # вторым аргументом является наблюдаемый объект параметрического типа AbstractVector{<:StockValue}}
    stockvalues = sc[2]

    # мы предварительно определяем несколько наблюдаемых объектов для отрезков
    # и столбчатых графиков, которые нужно отрисовать
    # это необходимо по той причине, что в Makie каждый шаблон должен обновляться в интерактивном режиме,
    # а для этого необходимо подключить механизм наблюдаемых объектов
    linesegs = Observable(Point2f[])
    bar_froms = Observable(Float32[])
    bar_tos = Observable(Float32[])
    colors = Observable(Bool[])

    # эта вспомогательная функция будет обновлять наблюдаемые объекты
    # при каждом изменении `times` или `stockvalues`
    function update_plot(times, stockvalues)
        colors[]

        # очищаем векторы внутри наблюдаемых объектов,
        empty!(linesegs[])
        empty!(bar_froms[])
        empty!(bar_tos[])
        empty!(colors[])

        # затем заполняем их обновленными значениями
        for (t, s) in zip(times, stockvalues)
            push!(linesegs[], Point2f(t, s.low))
            push!(linesegs[], Point2f(t, s.high))
            push!(bar_froms[], s.open)
            push!(bar_tos[], s.close)
        end
        append!(colors[], [x.close > x.open for x in stockvalues])
        colors[] = colors[]
    end

    # подключаем функцию `update_plot`, чтобы она вызывалась при каждом
    # изменении `times` или `stockvalues`
    Makie.Observables.onany(update_plot, times, stockvalues)

    # затем вызываем ее один раз вручную с первоначальным содержимым `times` и `stockvalues`,
    # чтобы предварительно заполнить все наблюдаемые объекты правильными значениями
    update_plot(times[], stockvalues[])

    # для цветов мы просто используем вектор логических значений или 0 и 1, которые
    # выполняют окрашивание в соответствии с 2-элементной цветовой картой
    # мы строим эту цветовую карту на основе `downcolor` и `upcolor`
    # мы присваиваем наблюдаемому объекту тип `Any`, чтобы он не выдавал ошибку при изменении
    # типа цвета с символа, например :red, на другой, допустим RGBf(1, 0, 1)
    colormap = Observable{Any}()
    map!(colormap, sc.downcolor, sc.upcolor) do dc, uc
        [dc, uc]
    end

    # на последнем шаге мы создаем график в объекте `sc` StockChart, что означает,
    # что наш новый график состоит из двух более простых шаблонов, наложенных
    # друг на друга
    linesegments!(sc, linesegs, color = colors, colormap = colormap)
    barplot!(sc, times, bar_froms, fillto = bar_tos, color = colors, strokewidth = 0, colormap = colormap)

    # наконец, мы возвращаем новый график StockChart
    sc
end

timestamps = 1:100

# мы создаем несколько фиктивных значений стоимости так, чтобы они неплохо выглядели в дальнейшем
startvalue = StockValue(0.0, 0.0, 0.0, 0.0)
stockvalues = foldl(timestamps[2:end], init = [startvalue]) do values, t
    open = last(values).close + 0.3 * randn()
    close = open + randn()
    high = max(open, close) + rand()
    low = min(open, close) - rand()
    push!(values, StockValue(
        open, close, high, low
    ))
end

# теперь можно использовать наш новый шаблон
f = Figure()

stockchart(f[1, 1], timestamps, stockvalues)

# и давайте попробуем изменить атрибуты по умолчанию
stockchart(f[2, 1], timestamps, stockvalues,
    downcolor = :purple, upcolor = :orange)
f

timestamps = Observable(collect(1:100))
stocknode = Observable(stockvalues)

fig, ax, sc = stockchart(timestamps, stocknode)

record(fig, "stockchart_animation.mp4", 101:200,
        framerate = 30) do t
    # добавляем новую метку времени, не активируя наблюдаемый объект
    push!(timestamps[], t)

    # добавляем новое значение StockValue, не активируя наблюдаемый объект
    old = last(stocknode[])
    open = old.close + 0.3 * randn()
    close = open + randn()
    high = max(open, close) + rand()
    low = min(open, close) - rand()
    new = StockValue(open, close, high, low)
    push!(stocknode[], new)

    # теперь метки времени и stocknode синхронизированы
    # снова, и мы можем активировать один из этих объектов, присвоив его самому себе,
    # чтобы обновить весь биржевой график для нового кадра
    stocknode[] = stocknode[]
    # давайте также обновим пределы осей, поскольку график будет расти
    # вправо
    autolimits!(ax)
end

module SomePackage

export someplot
export someplot!

# функции без методов
function someplot end
function someplot! end

end # модуль

module MakieExtension

using SomePackage
import SomePackage: someplot, someplot!

Makie.convert_single_argument(v::SomeVector) = v.v

@recipe(SomePlot) do scene
    Theme()
end

function Makie.plot!(p::SomePlot)
    lines!(p, p[1])
    scatter!(p, p[1])
    return p
end

end # модуль