Комплексные и рациональные числа

В Julia имеются предопределенные типы для комплексных и рациональных чисел, и для них поддерживаются все стандартные математические операции и элементарные функции. Кроме того, имеется система преобразования и продвижения, так что операции с любым сочетанием предопределенных числовых типов, будь то примитивных или составных, выполняются ожидаемым образом.

Комплексные числа

Глобальная константа im привязана к комплексному числу i, представляющему главное значение квадратного корня из --1. (От использования для этой глобальной константы обозначения, принятого в математике (i) или в инженерном деле (j), было решено отказаться из-за их распространенности в качестве имен индексных переменных.) Так как Julia позволяет записывать коэффициенты в виде числовых литералов рядом с именами переменных, этой привязки достаточно для удобной записи комплексных чисел, так же как это делается в математике:

julia> 1+2im
1 + 2im

С комплексными числами можно выполнять все стандартные арифметические операции:

julia> (1 + 2im)*(2 - 3im)
8 + 1im

julia> (1 + 2im)/(1 - 2im)
-0.6 + 0.8im

julia> (1 + 2im) + (1 - 2im)
2 + 0im

julia> (-3 + 2im) - (5 - 1im)
-8 + 3im

julia> (-1 + 2im)^2
-3 - 4im

julia> (-1 + 2im)^2.5
2.729624464784009 - 6.9606644595719im

julia> (-1 + 2im)^(1 + 1im)
-0.27910381075826657 + 0.08708053414102428im

julia> 3(2 - 5im)
6 - 15im

julia> 3(2 - 5im)^2
-63 - 60im

julia> 3(2 - 5im)^-1.0
0.20689655172413793 + 0.5172413793103449im

Механизм продвижения делает возможными сочетания операндов разных типов:

julia> 2(1 - 1im)
2 - 2im

julia> (2 + 3im) - 1
1 + 3im

julia> (1 + 2im) + 0.5
1.5 + 2.0im

julia> (2 + 3im) - 0.5im
2.0 + 2.5im

julia> 0.75(1 + 2im)
0.75 + 1.5im

julia> (2 + 3im) / 2
1.0 + 1.5im

julia> (1 - 3im) / (2 + 2im)
-0.5 - 1.0im

julia> 2im^2
-2 + 0im

julia> 1 + 3/4im
1.0 - 0.75im

Обратите внимание: 3/4im == 3/(4*im) == -(3/4*im), так как привязка литерального коэффициента имеет приоритет над делением.

Доступны стандартные функции для операций с комплексными значениями:

julia> z = 1 + 2im
1 + 2im

julia> real(1 + 2im) # вещественная часть z
1

julia> imag(1 + 2im) # мнимая часть z
2

julia> conj(1 + 2im) # комплексно сопряженное значение z
1 - 2im

julia> abs(1 + 2im) # абсолютное значение z
2.23606797749979

julia> abs2(1 + 2im) # абсолютное значение, возведенное в квадрат
5

julia> angle(1 + 2im) # фазовый угол в радианах
1.1071487177940904

Как и обычно, абсолютное значение (abs) комплексного числа — это его расстояние от нуля. Функция abs2 возвращает квадратный корень из абсолютного значения и особенно полезна для комплексных чисел, так как не извлекает квадратный корень. Функция angle возвращает фазовый угол в радианах (также называемый комплексным аргументом или просто аргументом). Для комплексных чисел также определен весь спектр других элементарных функций:

julia> sqrt(1im)
0.7071067811865476 + 0.7071067811865475im

julia> sqrt(1 + 2im)
1.272019649514069 + 0.7861513777574233im

julia> cos(1 + 2im)
2.0327230070196656 - 3.0518977991517997im

julia> exp(1 + 2im)
-1.1312043837568135 + 2.4717266720048188im

julia> sinh(1 + 2im)
-0.4890562590412937 + 1.4031192506220405im

Обратите внимание, что математические функции обычно возвращают вещественные значения при применении к вещественным числам, а комплексные — при применении к комплексным числам. Например, при применении к -1 и -1 + 0im функция sqrt ведет себя по-разному, несмотря на то, что -1 == -1 + 0im:

julia> sqrt(-1)
ERROR: DomainError with -1.0:
sqrt will only return a complex result if called with a complex argument. Try sqrt(Complex(x)).
Stacktrace:
[...]

julia> sqrt(-1 + 0im)
0.0 + 1.0im

Запись коэффициентов в виде числовых литералов не поддерживается при построении комплексных чисел из переменных. В этом случае умножение нужно записывать явным образом:

julia> a = 1; b = 2; a + b*im
1 + 2im

Однако делать это не рекомендуется. Вместо этого используйте более эффективную функцию complex для формирования комплексного значения напрямую из его вещественной и мнимой частей:

julia> a = 1; b = 2; complex(a, b)
1 + 2im

Операции умножения и сложения при этом не требуются.

Inf и NaN передаются через вещественную и мнимую части комплексного числа, как описано в разделе Особые значения с плавающей запятой:

julia> 1 + Inf*im
1.0 + Inf*im

julia> 1 + NaN*im
1.0 + NaN*im

Рациональные числа

В Julia есть тип рациональных чисел, представляющий точные значения целочисленных дробей. Рациональные числа создаются с помощью оператора //:

julia> 2//3
2//3

Если у числителя и знаменателя дроби есть общий множитель, они приводятся к несократимому виду так, чтобы знаменатель был неотрицательным:

julia> 6//9
2//3

julia> -4//8
-1//2

julia> 5//-15
-1//3

julia> -4//-12
1//3

Такая нормализованная форма целочисленной дроби уникальна, поэтому проверить рациональные значения на равенство можно путем проверки равенства их числителей и знаменателей. Нормализованные числитель и знаменатель рационального значения можно получить с помощью функций numerator и denominator:

julia> numerator(2//3)
2

julia> denominator(2//3)
3

Сравнивать числитель и знаменатель напрямую обычно не требуется, так как для рациональных значений определены стандартные арифметические операции и операции сравнения:

julia> 2//3 == 6//9
true

julia> 2//3 == 9//27
false

julia> 3//7 < 1//2
true

julia> 3//4 > 2//3
true

julia> 2//4 + 1//6
2//3

julia> 5//12 - 1//4
1//6

julia> 5//8 * 3//12
5//32

julia> 6//5 / 10//7
21//25

Рациональные числа можно легко преобразовывать в числа с плавающей запятой:

julia> float(3//4)
0.75

При преобразовании рациональных чисел в числа с плавающей запятой для любых целочисленных значений a и b, кроме двух случаев b == 0 и a == 0 && b < 0, соблюдается следующее тождество:

julia> a = 1; b = 2;

julia> isequal(float(a//b), a/b)
true

Допускается создание бесконечных рациональных значений:

julia> 5//0
1//0

julia> x = -3//0
-1//0

julia> typeof(x)
Rational{Int64}

Однако попытка создать рациональное значение NaN приведет к ошибке:

julia> 0//0
ERROR: ArgumentError: invalid rational: zero(Int64)//zero(Int64)
Stacktrace:
[...]

Как и обычно, система продвижения позволяет легко осуществлять операции с другими числовыми типами:

julia> 3//5 + 1
8//5

julia> 3//5 - 0.5
0.09999999999999998

julia> 2//7 * (1 + 2im)
2//7 + 4//7*im

julia> 2//7 * (1.5 + 2im)
0.42857142857142855 + 0.5714285714285714im

julia> 3//2 / (1 + 2im)
3//10 - 3//5*im

julia> 1//2 + 2im
1//2 + 2//1*im

julia> 1 + 2//3im
1//1 - 2//3*im

julia> 0.5 == 1//2
true

julia> 0.33 == 1//3
false

julia> 0.33 < 1//3
true

julia> 1//3 - 0.33
0.0033333333333332993