Преобразования размеров

using CairoMakie
using CairoMakie, Makie.Dates, Makie.Unitful

f, ax, pl = scatter(rand(Second(1):Second(60):Second(20*60), 10))

scatter!(ax, rand(Hour(1):Hour(1):Hour(20), 10))
# Единицы измерения также поддерживаются
scatter!(ax, LinRange(0u"yr", 0.1u"yr", 5))
f

try
    scatter!(ax, 1:4)
catch e
    return e
end

try
    scatter!(ax, LinRange(0u"yr", 0.1u"yr", 10), rand(Hour(1):Hour(1):Hour(20), 10))
catch e
    return e
end

(ax.dim1_conversion[], ax.dim2_conversion[])

f = Figure()
ax = Axis(f[1, 1]; dim1_conversion=Makie.CategoricalConversion())

struct MyDimConversion <: Makie.AbstractDimConversion end

# Целевой тип конвертации размера
struct MyUnit
    value::Float64
end

# В настоящее время это необходимо, поскольку `expand_dimensions` может быть ограниченно определено в Makie только для `Vector{<:Real}`.
# Поэтому, чтобы вызов `plot(some_y_values)` работал для ваших собственных типов, вам нужно определить этот метод:
Makie.expand_dimensions(::PointBased, y::AbstractVector{<:MyUnit}) = (keys(y.values), y)

function Makie.needs_tick_update_observable(conversion::MyDimConversion)
    # Возвращает наблюдаемый объект, указывающий, когда необходимо обновлять деления, например в случае изменения единицы измерения или добавления новых категорий.
    # Для простой конвертации единиц это не требуется, поэтому возвращается nothing.
    return nothing
end

# Указывает, что данный тип следует конвертировать с помощью MyDimConversion
# Тип извлекается посредством `Makie.get_element_type(plot_argument_for_dim_n)`,
# поэтому, например, `plot(1:10, ["a", "b", "c"])` вызывает `Makie.get_element_type(["a", "b", "c"])` и возвращает `String` для размера оси 2.
Makie.create_dim_conversion(::Type{MyUnit}) = MyDimConversion()

# Эту функцию также необходимо перегрузить, хотя в некотором смысле это избыточно в отношении предыдущей перегрузки.
# Мы не хотели использовать `hasmethod(MakieCore.should_dim_convert, (MyDimTypes,))`, потому что это может быть медленным и приводить к ошибкам.
Makie.MakieCore.should_dim_convert(::Type{MyUnit}) = true

# Версия фактической функции конвертации без наблюдаемого объекта
# Требуется для конвертации пределов осей и должно быть чистой версией приведенной ниже функции `convert_dim_observable`
function Makie.convert_dim_value(::MyDimConversion, values)
    return [v.value for v in values]
end

function Makie.convert_dim_observable(conversion::MyDimConversion, values_obs::Observable, deregister)
    # Здесь выполняется собственно конвертация
    # Большинство сложных конвертаций размеров должно производиться с наблюдаемым объектом (например, для создания словаря всех используемых категорий), поэтому одной функции `convert_dim_value` недостаточно.
    result = Observable(Float64[])
    f = on(values_obs; update=true) do values
        result[] = Makie.convert_dim_value(conversion, values)
    end

    # Любая операция с наблюдаемым объектом, такая как `on` или `map`, должна отправляться в `deregister` для правильной очистки состояния, например при уничтожении графика.
    # для `result = map(func, values_obs)` можно использовать `append!(deregister, result.inputs)`
    push!(deregister, f)
    return result
end

function Makie.get_ticks(::MyDimConversion, user_set_ticks, user_dim_scale, user_formatter, limits_min, limits_max)
    # В этом примере ничего особенного с делениями делать не нужно, просто добавьте `myunit` к меткам и предоставьте все остальное обычным методам поиска делений из Makie.
    ticknumbers, ticklabels = Makie.get_ticks(user_set_ticks, user_dim_scale, user_formatter, limits_min,
                                        limits_max)
    return ticknumbers, ticklabels .* "myunit"
end

barplot([MyUnit(1), MyUnit(2), MyUnit(3)], 1:3)