数理统计

在这个例子中，我们将演示如何解决数理统计领域的简单问题-获得一系列随机数，建模离散分布，构造正态分布随机变量的概率密度，以及卡尔曼滤波的

首先，执行预备单元格以设置图形渲染。

Pkg.add(["Distributions", "LinearAlgebra", "StatsBase", "Measures"])

using LaTeXStrings;
using Plots

gr()
#plotlyjs(); # Для интерактивных графиков

Plots.GRBackend()

随机变量的实现

**任务：**从方差为1，数学期望为-2的随机变量的正态分布中显示一百个点。

n = 100;
ϵ = randn(n) .- 2;
plot(1:n, ϵ, label=L"\mathcal{N}(-2, 1)")

离散分布：玩骰子

**任务：**比较一个随机变量的两个分布，该变量描述了通过蒙特卡罗方法和库获得的一个六边形模具的滚动结果 Distributions.

using Distributions, StatsBase, Plots;

faces, N = 1:6, 10^4
mcEstimate = counts(rand(faces,N), faces)/N

a = Distributions.DiscreteUniform(1,6)

plot(faces, mcEstimate, line=:stem, marker=:circle, c=:blue,
    ms=10, msw=0, lw=8, label="Монте-Карло", xticks=1:12, )

plot!([i for i in faces], [pdf(a, x) for x in faces], line=:stem, label="Плотность",
    lw=5, lc=:skyblue,
    xlabel="Выпавшее число", ylabel="Вероятность", ylims=(0,0.22))

##正常随机变量的概率密度

**任务：**绘制数学期望为1.5，方差为3.1的分布的概率密度。

using Distributions, Plots, LaTeXStrings
d = Normal(1.5, 3.1)

x = sort!(rand(d,1000))
y = pdf.(d, x)

plot(x, y, label=L"\frac{1}{\sqrt{2 \pi \sigma^2}} \exp \left( - \frac{(x - \mu)^2}{2 \sigma^2} \right)")
ylabel!(L"f(x; \mu, \sigma)")

卡尔曼滤波的一维示例[1,p.343]

许多物理性质的系统可以使用以下形式的模型来描述:

卡尔曼滤波器中的增益矩阵可以迭代计算以改善滤波结果。在此示例中，所有变量都是标量。我们相信且模型随力趋于0 每时每刻。

**任务：**演示卡尔曼滤波器跟踪一维自回归过程的能力。

using Distributions, LinearAlgebra, Random, Measures, Plots;
Random.seed!(1)

a, varXi, varZeta, = 0.8, 0.36, 1.0
X0, spikeTime, spikeSize = 10.0, 50, -20.0
Tsmall, Tlarge, warmTime = 100, 10^6, 10^4
kKalman = 0.3

function luenbergerTrack(k, T, spikeTime = Inf)
    X, Xhat = X0, 0.0
    xTraj, xHatTraj, yTraj = [X], [Xhat,Xhat], [X0]

    for t in 1:T-1
        X = a*X + rand(Normal(0,sqrt(varXi)))
        Y = X + rand(Normal(0,sqrt(varZeta)))
        Xhat =a*Xhat - k*(Xhat - Y)
        
        push!(xTraj,X)
        push!(xHatTraj,Xhat)
        push!(yTraj,Y)
    
        if t == spikeTime
            X += spikeSize
        end
    end
    deleteat!(xHatTraj,length(xHatTraj))
    xTraj, xHatTraj, yTraj
end

smallTraj, smallHat, smallY = luenbergerTrack(kKalman, Tsmall, spikeTime)

p1 = scatter(smallTraj, c=:blue, ms=3, msw=0, label="Траектория системы")
p1 = scatter!(smallY, c = :black, ms=3, msw=0, label="Измерения")
p1 = scatter!(smallHat,c=:red, ms=3, msw=0, label="Kalman filter tracking",
xlabel = "Время", ylabel = "Температура", xlims=(0, Tsmall))

kRange = 0.2:0.005:0.4
errs = []
for k in kRange
    xTraj, xHatTraj, _ = luenbergerTrack(k, Tlarge)
    mse = norm(xTraj[warmTime:end] - xHatTraj[warmTime:end])^2/(Tlarge-warmTime)
    push!(errs, mse)
end

analyticErr(k) = (varXi + k^2*varZeta) / (1-(a-k)^2)

p2 = scatter(kRange,errs, c=:black, ms=3, msw=0,
xlabel="k", ylabel="СКО", label = "Monte Carlo")
p2 = plot!(kRange,analyticErr.(kRange), c = :red,
xlabel="k", ylabel="СКО", label = "Аналитик", ylim =(0.58,0.64))

plot(p1, p2, size=(1000,400), margin = 5mm)

连结

[1][统计与朱莉娅（书）]（https://dlib.hust.edu.vn/bitstream/HUST/18110/1/OER000000260.pdf ）