Engee 文档
Notebook

异步电动机矢量图的构建

此示例显示了在静态模式下为一相构建具有闭环转子(ADKZ)的异步电动机的旋转矢量图。

导言

ADKZ的矢量图说明了静力学中主要流量矢量、电机电压和电流的关系。 在发动机操作期间，所有矢量围绕转子的旋转轴线在横截面平面内旋转，同时它们的模块和相移发生变化。

在该计算中，为处于稳态的发动机的相位a构建图（矢量的长度和相位不改变）。 矢量的模块和相位是根据MTK011-6起重机-冶金发动机的护照数据基于示例中计算的替代方案计算的。

发动机计算

让我们根据有问题的ADKZ的护照数据确定初始数据。:

In [ ]: 
# Паспортные данные двигателя МТК011-6
Pₙ = 1400; Uₙ = 380; f₁ = 50;           # Номинальная мощность [Вт], линейное напряжение [В], частота [В]
nₙ = 870; p = 3; η = 0.72;              # Номинальная частота вращения [об/мин], число пар полюсов, КПД
cosϕ = 0.69; Iₙ = 4.8; I₀ = 3.2;        # Номинальный коэффициент мощности, номинальный ток [А], ток холостого хода [А]
ki = 3; mₚ = 2.8; mₘ = 2.8; J = 0.02;   # Коэффициенты максимального тока, пускового и максимального момента, момент инерции двигателя [кг·м²]

现在让我们继续计算ADKZ替换方案的参数。:

In [ ]: 
# Расчёт параметров схемы замещения
U₁ = Uₙ/sqrt(3);                           # Номинальное фазное напряжение статора [В]
n₀ = 60*f₁/p;                             # Синхронная частота вращения [об/мин]
sₙ = (n₀-nₙ)/n₀; sₖ = sₙ*(mₘ+sqrt(mₘ^2-1)); # Номинальное и критическое скольжение
ω₀ = 2π*f₁/p; ωₙ = π*nₙ/30;                # Синхронная и номинальная углова скорость ротора [рад/с]
Mₙ = Pₙ/ωₙ; Mₘ = Mₙ*mₘ; Mₚ = Mₙ*mₚ;           # Номинальный, максимальный и пусковой момент [Н·м]
pₘ = 0.05*Pₙ;                              # Механические потери (5% от Pₙ) [Вт]
C = 0.8093072740472634;                   # Конструктивный коэффициент (предварительный)

R₂ = 1/3*(Pₙ+pₘ)/(Iₙ^2*(1-sₙ)/sₙ);              # Приведённое активное сопротивление роторной обмотки [Ом]
R₁ = U₁*cosϕ*(1-η)/Iₙ - C^2*R₂ - pₘ/(3*Iₙ^2);  # Активное сопротивление статорной обмотки [Ом]

L₁σ = L₂σ = U₁/(4π*f₁*(1+C^2)*ki*Iₙ);          # Индуктивности рассеивания статора и приведённое ротора [Гн]
L₁ = L₂ = U₁/(2π*f₁*Iₙ*sqrt(1-cosϕ^2)-2/3*(2π*f₁*Mₘ*sₙ)/(p*U₁*sₖ)); # Индуктивности статора и приведённое ротора [Гн]
Lm = L₁ - L₁σ;                                 # Индуктивность магнитной цепи [Гн]

C = 1 + L₁σ/Lm                             # Конструктивный коэффициент (уточнённый)

X₁σ = 2π*f₁*L₁σ;    X₂σ = 2π*f₁*L₂σ        # Реактивные сопротивления рассеивания статора и приведённое ротора [Ом]

I₂ = U₁/hypot(R₁+R₂*(1+(1-sₙ)/sₙ), X₁σ+X₂σ) # Ток ротора [А] (предварительное значение)
ψ₂ = atan(X₂σ*sₙ/R₂);                       # Угол запаздывания тока ротора [рад] (к эдс ротора, предварительное значение)

为了进一步计算和构建，我们转向电流和电压的复杂表示。 必须首先定义辅助函数。

辅助功能

以下功能可让您在将来简洁地准备矢量图的区域。

In [ ]: 
"""
    coordinateplane(заголовок::String, длина_оси)

Функция для построения координатный осей.
Plots, бэкенд GR.
Получает значение атрибута title и длину оси (X или Y)
Масштаб осей одинаков, подписи графиков - вверху слева
"""
function coordinateplane(заголовок::String, длина_оси)
    gr()
    plot(size=(500, 500), legend=:topleft, aspect_ratio=:equal,
        xlabel="Ось X", ylabel="Ось Y",
        title=заголовок, showaxis = false)
    quiver!([-длина_оси/2], [0], quiver=([длина_оси], [0]), color=:grey, width = 2) # Ось X
    quiver!([0], [-длина_оси/2], quiver=([0], [длина_оси]), color=:grey, width = 2) # Ось Y
end;

下面的函数结合了预处理复杂向量的指令-缩放和旋转，以及构建相对于前一个的复杂向量。

In [ ]: 
"""
    vectorplot(начальный::ComplexF64, результирующий::ComplexF64,
               цвет::Symbol=:black, лэйбл::String="")

Функция для построения результирующего вектора, исходящего из начального.
Plots, бэкенд GR.
Получает комплексные значения начального и результирующего векторов, атрибуты color и label результирующего.
Атрибуты поворот и множитель используются для вращения результирующего вектора на заданный угол [рад] и масштабирования соответственно.
Перед использованием рекомендуется выполнить coordinateplane().
"""
function vectorplot(начальный::ComplexF64, результирующий::ComplexF64, цвет::Symbol=:black, лэйбл::String="", поворот=0.0, множитель=1.0)
    начальный = начальный*множитель*exp(поворот*im)             # Поворот и масштабирование
    результирующий = результирующий*множитель*exp(поворот*im)   # Поворот и масштабирование
    Plots.quiver!([real(начальный)], [imag(начальный)], quiver=([real(результирующий)], [imag(результирующий)]), color=цвет, label=лэйбл)
end;

电流矢量图的构建

让我们定义电流的复数矢量:

In [ ]: 
Ȯ = 0.0 + 0.0*im                # Нуль-вектор в начале координат
İ₀ = I₀ + 0.0*im                # Комплексный ток холостого хода. Активная составляющая принимается равной 0.0 [A]
İ₂ = I₂*exp((3π/2-ψ₂)*im)       # Комплексный ток ротора [A]
İ₁ = İ₀ - İ₂;                   # Комплексный ток статора [A]

让我们构建一个电流的矢量图:

In [ ]: 
coordinateplane("Векторная диаграмма токов\n асинхронного двигателя", 20)

vectorplot(Ȯ,   İ₀,     :blue,     "İ₀, [A]")
vectorplot(İ₀,  -İ₂,    :green,    "-İ₂, [A]")
vectorplot(Ȯ,   İ₁,     :red,      "İ₁, [A]")
vectorplot(Ȯ,   İ₂,     :magenta,  "İ₂, [A]")
Out[0]:

图的一般外观，以及矢量相对于彼此和平面上的位置，对应于预期。 让我们继续指定矢量的参数并构建矢量应力图。

矢量应力图的构建

让我们定义复数电压和电动势矢量:

In [ ]: 
Ż₁ = R₁ + X₁σ*im        # Полное комплексное сопротивление цепи статора [В]
Ů₁_r = İ₁*R₁            # Активное падение напряжения в цепи статора [В]
Ů₁_x = İ₁*X₁σ*im        # Реактивное падение напряжения в цепи статора [В]
Ů₁_z = İ₁*Ż₁            # Полное падение напряжения в цепи статора [В]

Ů₁ = U₁*im              # Комплексное напряжение питания [В]
Ė₁ = Ė₂ = Ů₁_z - Ů₁;    # Эдс статора и приведённая ротора [В]

让我们指定平面上的位置和复矢量的参数:

In [ ]: 
Ė₁ = Ė₂ = abs(Ė₁)*exp(-π/2*im)     # Эдс статора и приведённая ротора [В] (отложено вдоль комплексной оси)
Ů₁ = -Ė₁ + Ů₁_z                    # Напряжение питания [В] (с учётом поворота вектора эдс)     

I₂ = abs(Ė₂)/hypot((R₂/sₙ), X₂σ)    # Приведённый модуль тока ротора [А] (уточнённое значение)
ψ₂ = atan(X₂σ*sₙ/R₂)                # Угол запаздывания тока ротора [рад] (уточнённое значение)
İ₂ = I₂*exp((3π/2-ψ₂)*im)          # Приведённый комплексный ток ротора [А]

İ₁ = İ₀ - İ₂                       # Комплексный ток статора [A] (уточнённый)

Ů₂_r = İ₂*(R₂ + R₂*(1-sₙ)/sₙ)       # Приведённое активное падение напряжения в цепи ротора [В]
Ů₂_x = İ₂*X₂σ*im;                  # Приведённое реактивное падение напряжения в цепи ротора [В]

让我们构建一个ADKZ应力的矢量图:

In [ ]: 
coordinateplane("Векторная диаграмма напряжений\n асинхронного двигателя", 500)

vectorplot(Ȯ,        -Ė₁,   :green,   "-Ė₁, [В]")
vectorplot(-Ė₁,      Ů₁_r,  :blue,    "Ů₁_r, [В]")
vectorplot(-Ė₁+Ů₁_r, Ů₁_x,  :orange,  "Ů₁_x, [В]")
vectorplot(-Ė₁,      Ů₁_z,  :purple,  "Ů₁_z, [В]")
vectorplot(Ȯ,        Ů₁,    :red,     "Ů₁, [В]")
vectorplot(Ȯ,        Ė₁,    :magenta, "Ė₁, [В]")
vectorplot(Ȯ,        Ů₂_r,  :blue,    "Ů₂_r, [В]")
vectorplot(Ů₂_r,     Ů₂_x,  :orange,  "Ů₂_x, [В]")
Out[0]:

电压图也对应于预期参数。 最后，我们将构建一个在复平面上旋转的电流和电压的完整图。

构建旋转矢量图

设置将动画的旋转周期。
为了清楚起见，我们将缩放当前向量。

In [ ]: 
RotateDiagram = @animate for δ in range(0.0, step=2π/100, length = 100)
    coordinateplane("Векторная диаграмма\n асинхронного двигателя", 500)

    vectorplot(Ȯ,  İ₀,  :blue,    "İ₀·15, [A]",  δ, 15)
    vectorplot(İ₀, -İ₂, :green,   "-İ₂·15, [A]", δ, 15)
    vectorplot(Ȯ,  İ₁,  :red,     "İ₁·15, [A]",  δ, 15)
    vectorplot(Ȯ,  İ₂,  :magenta, "İ₂·15, [A]",  δ, 15)

    vectorplot(Ȯ,           -Ė₁,  :green,   "-Ė₁, [В]",   δ)
    vectorplot(-Ė₁,         Ů₁_r, :blue,    "Ů₁_r, [В]",  δ)
    vectorplot((-Ė₁+Ů₁_r),  Ů₁_x, :orange,  "Ů₁_x, [В]",  δ)
    vectorplot(-Ė₁,         Ů₁_z, :purple,  "Ů₁_z, [В]",  δ)
    vectorplot(Ȯ,           Ů₁,   :red,     "Ů₁, [В]",    δ)
    vectorplot(Ȯ,           Ė₁,   :magenta, "Ė₁, [В]",    δ)
    vectorplot(Ȯ,           Ů₂_r, :blue,    "Ů₂_r, [В]",  δ)
    vectorplot(Ů₂_r,        Ů₂_x, :orange,  "Ů₂_x, [В]",  δ)
end

gif(RotateDiagram, "RotateDiagram.gif", fps = 20)

[ Info: Saved animation to /user/alexevs/_new/induction_motor_vector_diagram/RotateDiagram.gif
Out[0]:
No description has been provided for this image

应该注意的是，图中矢量的旋转频率已经降低，以允许旋转分析250倍（从50到1/5Hz）。

结论

作为脚本的结果，我们获得了在复平面上旋转的ADKZ电流和电压的旋转矢量图。 该示例的进一步可能的扩展包括阐明替代方案和矢量的计算，以动态模式（负载调节，加速或减速）构造图，以及构造用于三个相位的图-对称和不对称。

使用过的文献列表

  1. **Voldek A.I.**电机。 高等工程院校学生教材。 -第3版。，转载。 -L.：Energiya，1978。 -832页，生病了。
  2. **Vyoshenevsky S.N.**电动驱动器中电机的特性-第6版。，ispr。 -M.：能源，1977年。 -431页，生病了。