Engee 文档
Notebook

雷达接收机测试信号仿真

此示例演示如何模拟单稳态脉冲雷达的接收信号，以估计到目标的范围。 单稳态雷达具有位于接收器旁边的发射器。 发射器产生击中目标的脉冲并导致由接收器接收回波。 通过测量回波信号随时间的位置，可以估计到目标的范围。

本示例致力于开发能够实现指定技术特性的脉冲雷达系统。 它描述了将探测概率和范围分辨率等设计规范转换为发射机功率和脉冲持续时间等雷达系统参数的步骤。 还模拟了用于接收反射信号的环境和目标。 最后，将信号处理方法应用于接收信号以确定到目标的范围。

使用的函数

In [ ]: 
Pkg.add(["DSP"])

   Resolving package versions...
  No Changes to `~/.project/Project.toml`
  No Changes to `~/.project/Manifest.toml`
In [ ]: 
using DSP

# Функция для построения выходного отклика радара и порогового значения
function RadarPulsePlot(ReceivePulse,threshold,t,tp,num_plot::Int64)
    thresh = sqrt(threshold)*ones(length(t),num_plot)
    ReceivePulse =  Float64.(pow2db.((abs.(ReceivePulse)).^2))
    ReceivePulse[ReceivePulse.==0] .= eps(0.)
    thresh .=  pow2db.(thresh.^2)
    t = repeat(t,1,num_plot) .+ tp[1:num_plot]'
    text_title = reshape(["Импульс № $(i)" for i in 1:num_plot],1,num_plot)
    xlabel_text = [reshape(repeat([""],1,num_plot-1),1,num_plot-1) "Время, с"]
    plot(t,ReceivePulse[:,1:num_plot],layout=(num_plot,1),label="",title = text_title,
        fontfamily="Computer Modern", titlefontsize=10, guidefontsize=10, tickfontsize=10,gridalpha=0.3,lw=1.2)
    plot!(t,thresh[:,1:num_plot],layout=(num_plot,1),xlabel=xlabel_text,lw=1.2,
        ylabel = repeat(["Мощность, дБВт"],1,num_plot),label="",ls=:dash) # 
end;

# Функция для расчета мощности шума
function noisepow1(nbw::Number, nf::Number = 0, reftemp::Number = 290)
    function systemp(nf::Number,reftemp::Number = 290)
        nf >= 0 || error("Invalid input")
        nfLinear = db2pow(nf); 
        stemp = reftemp*(nfLinear); # Kelvin
        return stemp
    end
    B = 1.380649e-23
    npow =  B * systemp(nf,reftemp) * nbw
    return npow 
end;

设备的技术特点

开发这种脉冲雷达系统的目的是探测雷达截面（rcs）至少为1的非波动目标 距离雷达5000米，范围分辨率为50米。 期望的性能指标是0.9检测概率(Pd)和更少的虚警概率(Pfa)。 . 由于相干检测需要相位信息，因此计算昂贵，我们使用非相干检测方案。 此外，此示例假定环境处于可用空间中。

In [ ]: 
pd = 0.9; # Вероятность верного обнаружения
pfa = 1e-6; # Вероятность ложной тревоги
max_range = 5000; # [м] Максимальная дальность
range_res = 50; # [м] Требуемое разрешение по дальности
tgt_rcs = 1;  # [м^2] ЭПР цели

单稳态雷达系统的设计

我们需要识别雷达系统的几个特征，例如用于发射和接收信号的波形，接收器，发射器和天线。

发电机

在这个例子中，我们选择了一个矩形波形。 所需的范围分辨率决定了波形的带宽，在矩形波形的情况下，它决定了脉冲宽度。

脉冲波形的另一个重要参数是脉冲重复率(PRF)。 PRF由最大个位数范围确定。

In [ ]: 
prop_speed = physconst("lightspeed"); # [м/с] Скорость распространения
pulse_bw = prop_speed/(2*range_res);  # [Гц] Полоса импульса в частотной области
pulse_width = 1/pulse_bw; # [c] Длительность импульса
prf = prop_speed/(2*max_range); # [Гц] Частота следования импульсов
fs = 2*pulse_bw; # [Гц] Частота дискретизации системы
waveform = EngeePhased.RectangularWaveform(PulseWidth=1/pulse_bw,PRF=prf,SampleRate=fs); # системый объект

请注意，我们已将采样率设置为带宽的两倍。

接收机噪声特性

我们假设接收器中唯一存在的噪声是热噪声，因此在该仿真中没有干扰。 热噪声的功率取决于接收器的带宽。 接收器的噪声带宽被设置为等于波形的带宽。 在实际系统中通常是这种情况。 我们还假设接收器的增益为20dB，噪声系数为0dB。

In [ ]: 
noise_bw = pulse_bw; # [Гц] шумовая полоса приемника
receiver = EngeePhased.ReceiverPreamp(
    Gain=20, # [дБ] усиление 
    NoiseFigure=0,# [дБ] фактор шума
    SampleRate=fs, # [Гц] частота дискретизации
    EnableInputPort=true # порт для синхронизации передатчика и приемника
);

请注意，由于我们正在模拟单稳态雷达，因此在发射器关闭之前，接收器无法打开。 因此，我们设置标志 EnableInputPort=true 从而同步信号可以从发射机发射到接收机。

发射器

发射机最重要的参数是峰值功率。 所需的峰值功率与许多因素有关，包括最大个位数范围、接收机中所需的SNR和脉冲宽度。 在这些因素中，接收机中所需的SNR由Pd和Pfa的设计目的以及在接收机中实现的检测方案决定。

Pd、Pfa和SNR之间的关系可以最好地用接收机的操作性能曲线(ROC)来表示。 我们可以使用以下命令构造一条曲线，其中Pd是各种Snr的Pfa的函数:

In [ ]: 
snr_db = [-Inf, 0.0, 3, 10, 13]; # значения ОСШ в дБ
rocsnr(snr_db,SignalType="NonfluctuatingNoncoherent") # построение характеристик обнаружения
Out[0]:

ROC曲线表明，为了满足设计目标，Pfa=1e-6和Pd=0.9;接收信号的SNR必须超过13dB。 这是一个相当高的要求，不是很实用。 为了使雷达系统更可行，我们可以使用脉冲累积技术来降低所需的SNR。 如果我们选择对10个脉冲进行积分，那么曲线可以如下构造:

In [ ]: 
num_pulse_int = 10;
rocsnr([0 3 5],SignalType="NonfluctuatingNoncoherent",NumPulses=num_pulse_int)
Out[0]:

我们可以看到所需功率已降至约5dB。 SNR的进一步降低可以通过积分更多脉冲来实现，但是可用于积分的脉冲数量通常由于目标移动或环境异质性而受到限制。

在上述方法中，SNR值是从曲线读取的，但通常希望仅计算所需值。 对于非相干检测方案，计算所需的SNR在理论上是相当困难的。 幸运的是，有很好的近似值，例如Albersham方程。 使用Albersham方程，所需的SNR值可以导出为

In [ ]: 
snr_min = albersheim(pd, pfa,N= num_pulse_int) # расчет ОСШ путем решения уравнения Альбршема
print("Минимальное ОСШ: $(round(snr_min;sigdigits=5)) дБ")

Минимальное ОСШ: 4.9904 дБ

一旦您在接收器处获得了所需的SNR值，就可以使用雷达方程计算发射器处的峰值功率。 这里我们假设发射机的增益为20dB。

要使用雷达方程计算峰值功率，我们还需要知道传播信号的波长，这与系统的工作频率有关。 在这里，我们将工作频率设置为10GHz。

In [ ]: 
tx_gain = 20; # [дБ] Усиление передатчика
fc = 10e9; # [Гц] несущая частота сигнала
lambda = prop_speed/fc; # [м] длина волны сигнала
peak_power = ((4*pi)^3*noisepow1(1/pulse_width)*max_range^4*
    DSP.db2pow(snr_min))/(DSP.db2pow(2*tx_gain)*tgt_rcs*lambda^2) # пиковая мощность
print("Пиковая мощность: $(peak_power*1e3) кВт")

Пиковая мощность: 5.22647386447291e6 кВт

请注意，产生的功率约为5kW，这是一个可接受的值。 为了比较，如果我们没有使用脉冲积分方法，峰值功率将是33kW，这是一个相当大的值。

收到所有这些信息后，我们可以设置发射器。

In [ ]: 
transmitter = EngeePhased.Transmitter(
    Gain=tx_gain, # [дБ] усиление
    PeakPower=peak_power, # [Вт] пиковая мощность
    InUseOutputPort=true # включение выходного порта, который определяет 
                         # состояние передатчика (1 - вкл, 0 - выкл)
);

由于本示例模拟的是单稳态雷达系统，因此将InUseOutputPort端口设置为true以输出发射器的状态。 该状态信号可用于接通接收器。

发送和接收装置

在雷达系统中，信号作为电磁波传播。 因此，信号必须由雷达系统中使用的天线发射和收集。 这就是辐射和"收集"天线发挥作用的地方。

在单稳态雷达系统中，发射器和集电极使用相同的天线，因此首先我们将定义天线。 为了简化设计，我们选择了各向同性天线。 请注意，天线必须以系统的工作频率（10GHz）工作，因此我们将天线频率范围设置为5-15GHz。

我们假设天线是静止的。

In [ ]: 
# антенный элемент радара
antenna = EngeePhased.IsotropicAntennaElement(
    FrequencyRange=[5e9 15e9]); # [Гц] диапазон частот антенны излучения
# модель движения радара
sensormotion = EngeePhased.Platform(
    InitialPosition=[0; 0; 0], # [м] начальное положение антенны
    Velocity=[0; 0; 0]); # [м/с] скорость антенны

使用天线和工作频率，我们设置辐射器（Radiator）和接收天线（Collector）。

In [ ]: 
radiator = EngeePhased.Radiator(
    Sensor=antenna,             # задание антенного элемента 
    OperatingFrequency=fc);   # [Гц] задание несущей частоты

collector = EngeePhased.Collector(
    Sensor=antenna,             # задание  антенного элемента 
    OperatingFrequency=fc);     # [Гц] задание несущей частоты

这样就完成了雷达系统的配置。 在以下部分中，我们将定义建模所必需的其他对象，例如目标和环境。 然后我们将模拟信号的返回，并根据模拟的信号执行范围确定。

系统建模

目标

为了测试我们的雷达探测目标的能力，我们必须首先识别目标。 让我们假设空间中有3个静止的，非波动的目标。 它们的位置和雷达横截面如下所示。

In [ ]: 
tgtpos = [[2024.66;0;0] [3518.63;0;0] [3845.04;0;0]]; # [м] компоненты начального положения 3 целей [[px] [py] [pz]]
tgtvel = [[0;0;0] [0;0;0] [0;0;0]]; # [м/с] компоненты вектора скорости 3 целей [[vx] [vy] [vz]]
tgtmotion = EngeePhased.Platform(InitialPosition=tgtpos,Velocity=tgtvel); # модель движения целей

tgtrcs = [1.6 2.2 1.05]; # м^2 ЭПР целей
target = EngeePhased.RadarTarget(MeanRCS=tgtrcs,OperatingFrequency=fc); # Системный объект целей
分布环境

为了模拟信号，我们还需要确定雷达系统和每个目标之间的传播信道。

In [ ]: 
channel = EngeePhased.FreeSpace(
    SampleRate=fs, # [Гц] частота дискретизации
    TwoWayPropagation=true, # двунаправленное распространение
    OperatingFrequency=fc); # [Гц] несущая частота

由于本示例使用单稳态雷达系统，因此通道配置为模拟两个方向的传播延迟。

信号合成

现在我们已经准备好模拟整个系统。

合成信号是每列时间快（每个脉冲内部的时间）和每行时间慢（脉冲之间的时间）的数据矩阵。 为了可视化信号，定义快速时间网格和慢时间网格非常有用。

In [ ]: 
fast_time_grid = (0:1/fs:1/prf-1/fs); # [с] сетка быстрого времени
slow_time_grid = (0:num_pulse_int-1)./prf; # [c] сетка медленного времени

下一个周期模拟接收信号的10个脉冲。

让我们设置接收器中噪声发生器的初始状态，以便可以再现相同的结果。

In [ ]: 
release!(receiver) # доступ к обновлению параметров объекта
receiver.SeedSource = "Property";  # изменение тип модели генерации шума
receiver.Seed = 2007; # задание начального состояния генератора тепловых шумов

# Выделение памяти для результирующих данных
rxpulses = zeros(ComplexF64,length(fast_time_grid),num_pulse_int);

for m = 1:num_pulse_int
    
    # Обновление пложения радара и целей
    sensorpos,sensorvel = sensormotion(1/prf);
    tgtpos,tgtvel = tgtmotion(1/prf);

    # Расчет углов по дальности от радара до целей  
    global tgtrng,tgtang = rangeangle(tgtpos,sensorpos);
    
    # Моделирование распространения сигнала от радара до целей
    pulse = waveform(); # генератор прямоугольных импульсов
    txsig,txstatus = transmitter(pulse); # усилитель передающего сигнала
    txsig = radiator(txsig,tgtang); # излучение сигнала в среду распространения
    txsig = channel(txsig,sensorpos,tgtpos,sensorvel,tgtvel); # учет среды распространения
    
    # Отражение сигнала от целей с учетом ЭПР
    tgtsig = target(txsig);
    
    # Прием и предварительного усиление отраженного сигнала
    rxsig = collector(tgtsig,tgtang); # приемная антенна
    rxpulses[:,m] = receiver(rxsig,xor.(txstatus.>0,1)); # предусилитель
end

范围检测

阈值检测

检测器将信号强度与预设阈值进行比较。 在雷达应用中，通常选择阈值以使Pfa低于某一水平。 在这种情况下，我们假设噪声是白高斯并且检测是非相干的。 由于我们还使用10个脉冲对脉冲进行积分，因此阈值信号功率确定如下

In [ ]: 
npower = noisepow1(noise_bw,receiver.NoiseFigure,
    receiver.ReferenceTemperature);  # [Вт] мощность шума
threshold = npower * DSP.db2pow(npwgnthresh(pfa,num_pulse_int,"noncoherent")); # порог обнаружения

我们用阈值绘制前两个接收脉冲

In [ ]: 
num_pulse_plot = 2; # количество графиков
RadarPulsePlot(rxpulses,threshold,
    fast_time_grid,slow_time_grid,num_pulse_plot)
Out[0]:

这些附图中的阈值仅用于演示目的。 请注意，来自第二和第三个目标的信号比来自第一个目标的信号弱得多，因为它们距离雷达更远。 因此，接收信号的功率取决于范围，并且阈值对位于不同距离的目标是不公平的。

一致的过滤

匹配滤波器提供增加检测阈值的增强处理。 它将接收信号转换为发送振荡器类型的本地、时间反转和共轭副本。 因此，在创建匹配滤波器时，我们必须指定探测信号的类型。 在执行脉冲积分、阈值检测等之前，接收到的脉冲首先通过匹配滤波器以改善SNR。

In [ ]: 
matchingcoeff = getMatchedFilter(waveform); # расчет коэффициентов согласованного 
                                            # фильтра на основе изулченного сигнала          
matchedfilter = EngeePhased.MatchedFilter(
    Coefficients=matchingcoeff, # коэффициенты фильтра
    GainOutputPort=true); # выходной порт усиления
rxpulses, mfgain = matchedfilter(rxpulses); # отклик после согласованной фильтрации

匹配滤波器引入了内部延迟，因此峰值的位置不再与目标的真实位置匹配。 为了补偿这种延迟，我们将匹配滤波器的输出向前移动，并在最后添加零。 请注意，在实际系统中，由于数据是连续累积的，因此数组不会有尽头。

In [ ]: 
matchingdelay = size(matchingcoeff,1)-1; # длина коэффициентов согласованного фильтра
rxpulses = buffer(rxpulses[matchingdelay+1:end],200); # size(rxpulses,1) ->200

阈值随后将通过匹配滤波器的处理增益而增加。

In [ ]: 
threshold = threshold * db2pow(mfgain)

下图显示了通过匹配滤波器后的相同两个脉冲。

In [ ]: 
RadarPulsePlot(rxpulses,threshold,
    fast_time_grid,slow_time_grid,num_pulse_plot)
Out[0]:

在匹配滤波器级之后，SNR提高。 然而，由于接收信号的功率取决于范围，来自附近目标的信号仍然比来自位于更远距离的目标强得多。 因此，如上图所示，来自附近bean的噪声很有可能超过阈值并使目标更远的地方黯然失色。 为了确保阈值对于可检测范围内的所有目标都有效，我们可以使用时变增益因子来补偿接收回波信号中与范围相关的损失。

为了补偿与范围相关的损耗，我们首先计算对应于每个信号样本的选通脉冲，然后计算对应于每个选通脉冲的自由空间损耗。 接收到这些信息后，我们对接收到的脉冲施加时变增益，使返回看起来来自相同的参考范围（最大可检测范围）。

In [ ]: 
range_gates = prop_speed*fast_time_grid/2; # [м] разрешение по дальности
tvg = EngeePhased.TimeVaryingGain( # создание системного объекта ВАРУ
    RangeLoss=2*fspl.(range_gates,lambda), # [дБ] потери с учетом дальности
    ReferenceLoss=2*fspl.(max_range,lambda)); # [дБ] относительные потери при максимальной дальности
rxpulses = tvg(rxpulses); # выходной сигнал после работы ВАРУ

现在让我们在范围归一化后绘制相同的两个脉冲。

In [ ]: 
RadarPulsePlot(rxpulses,threshold,fast_time_grid,slow_time_grid,num_pulse_plot)
Out[0]:

随时间改变增益导致噪声电平的增加。 但是，目标的返回现在独立于范围。 现在可以使用恒定阈值在整个可检测范围内进行检测。

注意，在该阶段，阈值高于每个脉冲中包含的最大功率电平。 因此，在此阶段无法检测到任何内容。 我们需要对脉冲进行积分，以便来自目标的返回回波的功率超过阈值，并且噪声水平保持在条形之下。 这是可以预料的，因为正是脉冲积分使我们能够使用一系列低功率脉冲。

不连贯的积累

我们可以通过对接收到的脉冲进行非相干积分（视频积分）来进一步提高SNR。

In [ ]: 
rxpulses = pulsint(rxpulses,"noncoherent"); # некогерентное накопление
RadarPulsePlot(rxpulses,threshold,fast_time_grid,slow_time_grid,1)
Out[0]:

在视频集成阶段之后，数据准备用于最终检测阶段。 该图显示来自目标的所有三个回波信号都超过阈值，这意味着它们可以被检测到。

范围检测

最后，对积分脉冲执行阈值检测。 检测电路识别峰值，然后将其位置转换为目标范围。

In [ ]: 
_,range_detect = findpeaks(rxpulses,"MinPeakHeight",sqrt(threshold)); # обнаружение пиков

真实和检测到的目标范围如下所示:

In [ ]: 
true_range = round.(tgtrng;sigdigits=4)
range_estimates = round.(range_gates[range_detect];sigdigits=4)
println("Истинная дальность целей: $(true_range) м")
print("Оценка дальности целей: $(range_estimates) м")

Истинная дальность целей: [2025.0 3519.0 3845.0] м
Оценка дальности целей: [2025.0, 3525.0, 3850.0] м

请注意，这些范围估计值仅在雷达系统可以实现的范围分辨率（50m）下准确。

结论

在这个例子中，我们设计了一个基于一组设定目标的雷达系统。 基于这些目标，计算了雷达系统的许多设计参数。 该示例还展示了如何使用开发的雷达执行范围检测任务。 在本例中，雷达使用矩形波形。