violin
|
Страница в процессе перевода. |
#
Makie.violin — Function
violin(x, y)Отрисовывает график «скрипка».
Аргументы
-
x: позиции категорий. -
y: величины, плотность которых вычисляется.
Тип графика
Псевдоним типа графика для функции violin — Violin.
Примеры
using CairoMakie
categories = rand(1:3, 1000)
values = randn(1000)
violin(categories, values)
using CairoMakie
fig = Figure()
xs = vcat([fill(i, i * 1000) for i in 1:4]...)
ys = vcat(randn(6000), randn(4000) * 2)
for (i, scale) in enumerate([:area, :count, :width])
ax = Axis(fig[i, 1])
violin!(ax, xs, ys; scale, show_median=true)
Makie.xlims!(0.2, 4.8)
ax.title = "scale=:$(scale)"
end
fig
using CairoMakie
categories = rand(1:3, 1000)
values = map(categories) do x
return x == 1 ? randn() : x == 2 ? 0.5 * randn() : 5 * rand()
end
violin(categories, values, datalimits = extrema)
using CairoMakie
N = 1000
categories = rand(1:3, N)
dodge = rand(1:2, N)
side = rand([:left, :right], N)
color = @. ifelse(side === :left, :orange, :teal)
values = map(side) do s
return s === :left ? randn() : rand()
end
violin(categories, values, dodge = dodge, side = side, color = color)
using CairoMakie
N = 1000
categories = rand(1:3, N)
side = rand([:left, :right], N)
color = map(categories, side) do x, s
colors = s === :left ? [:red, :orange, :yellow] : [:blue, :teal, :cyan]
return colors[x]
end
values = map(side) do s
return s === :left ? randn() : rand()
end
violin(categories, values, side = side, color = color)
Использование статистических весов
using CairoMakie
using Distributions
N = 100_000
categories = rand(1:3, N)
values = rand(Uniform(-1, 5), N)
w = pdf.(Normal(), categories .- values)
fig = Figure()
violin(fig[1,1], categories, values)
violin(fig[1,2], categories, values, weights = w)
fig
Горизонтальная ось
using CairoMakie
fig = Figure()
categories = rand(1:3, 1000)
values = randn(1000)
ax_vert = Axis(fig[1,1];
xlabel = "categories",
ylabel = "values",
xticks = (1:3, ["one", "two", "three"])
)
ax_horiz = Axis(fig[1,2];
xlabel="values", # Обратите внимание, что x/y по-прежнему соответствуют горизонтальной/вертикальной осям, соответственно.
ylabel="categories",
yticks=(1:3, ["one", "two", "three"])
)
# Примечание. Одинаковый порядок категорий/значений, несмотря на разные оси.
violin!(ax_vert, categories, values) # По умолчанию используется `orientation=:vertical`
violin!(ax_horiz, categories, values; orientation=:horizontal)
fig
Атрибуты
clip_planes
Значение по умолчанию: automatic
Плоскости отсечения позволяют выполнять отсечение в трехмерном пространстве. Вы можете задать вектор длиной до 8 Plane3f здесь плоскости, за которыми участки будут обрезаны (т.е. станут невидимыми). По умолчанию плоскости клипа наследуются от родительского графика или сцены. Вы можете удалить родительский элемент clip_planes проходя мимо Plane3f[].
datalimits
Значение по умолчанию: (-Inf, Inf)
Укажите значения для обрезки violin. Это может быть Tuple или Function (например , datalimits=extrema).
depth_shift
Значение по умолчанию: 0.0
настраивает значение глубины участка после всех других преобразований, т.е. в пространстве клипа, где 0 <= depth <= 1. This only applies to GLMakie and WGLMakie and can be used to adjust render order (like a tunable overdraw).
fxaa
Значение по умолчанию: true
Регулирует, будет ли график отображаться с использованием fxaa (сглаживание, только GLMakie).
inspectable
Значение по умолчанию: @inherit inspectable
Определяет, должен ли этот график отображаться DataInspector. Значение по умолчанию зависит от темы родительской сцены.
inspector_clear
Значение по умолчанию: automatic
Устанавливает функцию обратного вызова (inspector, plot) -> ... для очистки пользовательских индикаторов в DataInspector.
inspector_hover
Значение по умолчанию: automatic
Устанавливает функцию обратного вызова (inspector, plot, index) -> ... который заменяет значение по умолчанию show_data методы.
inspector_label
Значение по умолчанию: automatic
Устанавливает функцию обратного вызова (plot, index, position) -> string , которая заменяет метку по умолчанию, сгенерированную DataInspector.
model
Значение по умолчанию: automatic
Задает матрицу модели для графика. Это отменяет корректировки, внесенные с помощью translate!, rotate! и scale!.
overdraw
Значение по умолчанию: false
Определяет, будет ли график отображаться поверх других графиков. В частности, это означает игнорирование проверок глубины в GL-интерфейсах
scale
Значение по умолчанию: :area
Масштабируйте плотность по площади (:area), количеству (:count) или ширине (:width).
side
Значение по умолчанию: :both
Указывать :left или :right чтобы изобразить скрипку только с одной стороны.
space
Значение по умолчанию: :data
задает область преобразования для прямоугольника, охватывающего участок. Видеть Makie.spaces() для получения возможных исходных данных.
ssao
Значение по умолчанию: false
Определяет, будет ли график отображаться с помощью ssao (screen space ambient occlusion). Обратите внимание, что это имеет смысл только для 3D-графиков и применимо только к fxaa = true.
transparency
Значение по умолчанию: false
Настраивает прозрачность графика. В GLMakie transparency = true в результате используется прозрачность, независимая от порядка.