barplot
|
Страница в процессе перевода. |
#
Makie.barplot — Function
barplot(positions, heights; kwargs...)Строит столбчатый график.
Тип графика
Псевдоним типа графика для функции barplot — BarPlot.
Примеры
using CairoMakie
f = Figure()
Axis(f[1, 1])
xs = 1:0.2:10
ys = 0.5 .* sin.(xs)
barplot!(xs, ys, color = :red, strokecolor = :black, strokewidth = 1)
barplot!(xs, ys .- 1, fillto = -1, color = xs, strokecolor = :black, strokewidth = 1)
f
using CairoMakie
xs = 1:0.2:10
ys = 0.5 .* sin.(xs)
barplot(xs, ys, gap = 0, color = :gray85, strokecolor = :black, strokewidth = 1)
using CairoMakie
tbl = (cat = [1, 1, 1, 2, 2, 2, 3, 3, 3],
height = 0.1:0.1:0.9,
grp = [1, 2, 3, 1, 2, 3, 1, 2, 3],
grp1 = [1, 2, 2, 1, 1, 2, 1, 1, 2],
grp2 = [1, 1, 2, 1, 2, 1, 1, 2, 1]
)
barplot(tbl.cat, tbl.height,
stack = tbl.grp,
color = tbl.grp,
axis = (xticks = (1:3, ["left", "middle", "right"]),
title = "Stacked bars"),
)
barplot(tbl.cat, tbl.height,
dodge = tbl.grp,
color = tbl.grp,
axis = (xticks = (1:3, ["left", "middle", "right"]),
title = "Dodged bars"),
)
barplot(tbl.cat, tbl.height,
dodge = tbl.grp1,
stack = tbl.grp2,
color = tbl.grp,
axis = (xticks = (1:3, ["left", "middle", "right"]),
title = "Dodged and stacked bars"),
)
colors = Makie.wong_colors()
# Рисунок и ось
fig = Figure()
ax = Axis(fig[1,1], xticks = (1:3, ["left", "middle", "right"]),
title = "Dodged bars with legend")
# График
barplot!(ax, tbl.cat, tbl.height,
dodge = tbl.grp,
color = colors[tbl.grp])
# Условные обозначения
labels = ["group 1", "group 2", "group 3"]
elements = [PolyElement(polycolor = colors[i]) for i in 1:length(labels)]
title = "Groups"
Legend(fig[1,2], elements, labels, title)
fig
barplot(
tbl.cat, tbl.height,
dodge = tbl.grp,
color = tbl.grp,
bar_labels = :y,
axis = (xticks = (1:3, ["left", "middle", "right"]),
title = "Dodged bars horizontal with labels"),
colormap = [:red, :green, :blue],
color_over_background=:red,
color_over_bar=:white,
flip_labels_at=0.85,
direction=:x,
)
using CairoMakie
barplot([-1, -0.5, 0.5, 1],
bar_labels = :y,
axis = (title="Fonts + flip_labels_at",),
label_size = 20,
flip_labels_at=(-0.8, 0.8),
label_color=[:white, :green, :black, :white],
label_formatter = x-> "Flip at $(x)?",
label_offset = 10
)
using CairoMakie
gantt = (
machine = [1, 2, 1, 2],
job = [1, 1, 2, 3],
task = [1, 2, 3, 3],
start = [1, 3, 3.5, 5],
stop = [3, 4, 5, 6]
)
fig = Figure()
ax = Axis(
fig[2,1],
yticks = (1:2, ["A","B"]),
ylabel = "Machine",
xlabel = "Time"
)
xlims!(ax, 0, maximum(gantt.stop))
cmap = Makie.to_colormap(:tab10)
barplot!(
gantt.machine,
gantt.stop,
fillto = gantt.start,
direction = :x,
color = gantt.job,
colormap = cmap,
colorrange = (1, length(cmap)),
gap = 0.5,
bar_labels = ["task #$i" for i in gantt.task],
label_position = :center,
label_color = :white,
label = ["job #$i" => (; color = i) for i in unique(gantt.job)]
)
Legend(fig[1,1], ax, "Jobs", orientation=:horizontal, tellwidth = false, tellheight = true)
fig
Атрибуты
alpha
Значение по умолчанию: 1.0
Альфа-значение цветовой карты или атрибута color. Несколько букв, таких как в plot(alpha=0.2, color=(:red, 0.5), будут умножены.
clip_planes
Значение по умолчанию: automatic
Плоскости обрезки позволяют выполнять обрезку в трехмерном пространстве. Вы можете задать вектор длиной до 8 Plane3f Здесь вы можете задать плоскости, за которыми участки будут обрезаны (т.е. станут невидимыми). По умолчанию плоскости клипа наследуются от родительского графика или сцены. Вы можете удалить родительский элемент clip_planes проходя мимо Plane3f[].
colormap
Значение по умолчанию: @inherit colormap :viridis
Устанавливает цветовую схему, которая выбирается для числовых значений. colors. PlotUtils.cgrad(...), Makie.Reverse(any_colormap) также можно использовать любой символ из ColorBrewer или PlotUtils. Чтобы просмотреть все доступные цветовые градиенты, вы можете позвонить по телефону Makie.available_gradients().
colorrange
Значение по умолчанию: automatic
Значения, представляющие начальную и конечную точки colormap.
colorscale
Значение по умолчанию: identity
Функция преобразования цвета. Может быть любой функцией, но хорошо работает только в сочетании с Colorbar для identity, log, log2, log10, sqrt, logit, Makie.pseudolog10 и Makie.Symlog10.
depth_shift
Значение по умолчанию: 0.0
настраивает значение глубины участка после всех других преобразований, т.е. в пространстве фрагмента, где 0 <= depth <= 1. This only applies to GLMakie and WGLMakie and can be used to adjust render order (like a tunable overdraw).
direction
Значение по умолчанию: :y
Управляет направлением столбцов, может быть :y (вертикальное) или :x (горизонтальное).
fillto
Значение по умолчанию: automatic
Управляет базовой линией столбцов. В случае автоматического режима по умолчанию это значение равно нулю, если только столбчатая диаграмма не построена на логарифмической шкале. При логарифмической шкале значение по умолчанию в автоматическом режиме равно половине минимального значения, поскольку ноль является недопустимым значением для логарифмической шкалы.
fxaa
Значение по умолчанию: true
Регулирует, будет ли график отображаться с использованием fxaa (сглаживание, только GLMakie).
gap
Значение по умолчанию: 0.2
Окончательная ширина полос рассчитывается как w * (1 - gap), где w — ширина каждой полосы, определяемая атрибутом width.
highclip
Значение по умолчанию: automatic
Цвет для любого значения, превышающего указанный цветовой диапазон.
inspectable
Значение по умолчанию: @inherit inspectable
Определяет, должен ли этот график отображаться в DataInspector. Значение по умолчанию зависит от темы родительской сцены.
inspector_clear
Значение по умолчанию: automatic
Sets a callback function (inspector, plot) -> ... для очистки пользовательских индикаторов в DataInspector.
inspector_hover
Значение по умолчанию: automatic
Устанавливает функцию обратного вызова (inspector, plot, index) -> ... которая заменяет функцию по умолчанию show_data методы.
inspector_label
Значение по умолчанию: automatic
Устанавливает функцию обратного вызова (plot, index, position) -> string , которая заменяет метку по умолчанию, сгенерированную DataInspector.
label_offset
Значение по умолчанию: 5
Расстояние от надписей до конца полосы указывается в экранных единицах. Не применяется, если label_position = :center.
label_position
Значение по умолчанию: :end
Положение метки каждого бара относительно самого бара. Возможны следующие значения :end или :center.
model
Значение по умолчанию: automatic
Задает матрицу модели для построения графика. Это отменяет корректировки, сделанные с помощью translate!, rotate! и scale!.
overdraw
Значение по умолчанию: false
Определяет, будет ли график отображаться поверх других графиков. Это, в частности, означает игнорирование проверок глубины в бэкендах GL
space
Значение по умолчанию: :data
задает область преобразования для прямоугольника, охватывающего участок. Видеть Makie.spaces() для получения возможных вводных данных.
ssao
Значение по умолчанию: false
Определяет, будет ли график отображаться с помощью ssao (screen space ambient occlusion). Обратите внимание, что это имеет смысл только для 3D-графиков и применимо только к fxaa = true.